Can I loop over existing resources and extract a property?

[oskbor]

Hi, I want to create an array where the values are extracted from existing resources.
This was my first attempt

var envVars = [
  'BASE_FRONT_END_URL'
  'AZURE_VOLUME_BASE_URL'
]
resource values 'Microsoft.AppConfiguration/configurationStores/keyValues@2021-03-01-preview' existing = [for name in envVars: {
  name: '${configStore}/${name}'
}]

var out= [for (env, i) in envVars: {
  name: env
  value: values[i].properties.value
}]

fails with the error:
This expression is being used in the for-body of the variable "out", which requires values that can be calculated at the start of the deployment. Properties of values which can be calculated at the start include "apiVersion", "id", "name", "type".bicep(BCP182)

Any ideas if/how I can accomplish this?

[alex-frankel]

Looks like an issue with our variable replacement logic. ARM has strict rules on when runtime values can be used in variables (and other locations), which is what you are being affected. In Bicep we do some magic to remove the variable in the generated template and "hardcode" the variable value wherever it is used. For some reason that is not happening here. @miqm / @anthony-c-martin -- can you take a look and see if we should convert this to an issue?

The workaround would be to not use a variable and move this code to wherever you plan to consume the variable. For example, if I want to output this value, this seems to work:

var envVars = [
  'BASE_FRONT_END_URL'
  'AZURE_VOLUME_BASE_URL'
]

var configStore = 'config-store-name'

resource values 'Microsoft.AppConfiguration/configurationStores/keyValues@2021-03-01-preview' existing = [for name in envVars: {
  name: '${configStore}/${name}'
}]

output out array = [for (env, i) in envVars: {
  name: env
  value: values[i].properties.value
}]

[brwilkinson]

actually that is actual keys, .. so this one?

https://docs.microsoft.com/en-us/rest/api/appconfiguration/configuration-stores/list-key-value

[brwilkinson]

@alex did you set the label on any of your keyValues?

looks like the existing will only retrieve the Key and not the associated label?

I found it works if you don't put any labels.

POST https://management.azure.com/subscriptions/b8f402aa-20f7-4888-b45c-3cf086dad9c3/resourceGroups/ACU1-BRW-AOA-RG-T5/providers/Microsoft.AppConfiguration/configurationStores/ACU1-BRW-AOA-T5-ac01/listKeyValue?api-version=2019-10-01

// with body

{
  "key": "Enviro",
}

returns

{
  "key": "Enviro",
  "label": null,
  "value": "",
  "contentType": "",
  "eTag": "ftR3TICvXNwjNVjGIPwHqHNrFoI",
  "lastModified": "2021-10-28T21:01:39+00:00",
  "locked": false,
  "tags": {}
}

Also if I add the label

{
  "key": "Region",
  "label": "Region"
}

returns

{
  "key": "Region",
  "label": "Region",
  "value": "Centralus",
  "contentType": "",
  "eTag": "3ehQjb1NPWFN6AW8TAyKph4HfX0",
  "lastModified": "2021-10-28T21:18:38+00:00",
  "locked": false,
  "tags": {}
}

In bicep, works without labels

var envVars = [
  'Enviro'
  'ENV'
]
var configStore = 'ACU1-BRW-AOA-T5-ac01'

resource values 'Microsoft.AppConfiguration/configurationStores/keyValues@2020-07-01-preview' existing = [for name in envVars: {
  name: '${configStore}/${name}'
  
}]

output values array = [for (item, index) in envVars: {
  key: values[index].properties.key
  label: values[index].properties.label
  value: values[index].properties.value
}]

Outputs                 :
                          Name             Type                       Value
                          ===============  =========================  ==========
                          values           Array                      [
                            {
                              "key": "Enviro",
                              "label": null,
                              "value": "T05"
                            },
                            {
                              "key": "ENV",
                              "label": null,
                              "value": "T"
                            }
                          ]

Now if I switch to the Region example that has a key and label it fails

Status Message: The resource with id 'Region' was not found

So I guess existing will not work, since it only allows you to provide the name, which is the key and not the label?

I wonder if the listkeyvalues works to pass in the body, with the key + label as arguments?

[brwilkinson]

okay I saw your other issue, relating to retrieving these values as a variable. i.e. not as input on a resource or an output.

So I see that is a different issue, ignore me.

[brwilkinson]

@oskbor I will mark this one as answered here, since the issue has now been open #5020

[oskbor]

Please do; and thank you all for your thorough answers. I haven't had the time to try but I'm confident that using the output array will remove the error.