Retrieving existing app center key #5413
-
|
In my bicep file I need to get the "APPINSIGHTS_INSTRUMENTATIONKEY" from the configuration. I'm new to biceps and i'm not sure how to reference this value and store in a variable. if I have "param AppInsightsId string" How can I reference that value to use in my bicep file? I tried this, but it's wrong |
Beta Was this translation helpful? Give feedback.
Answered by
brwilkinson
Dec 14, 2021
Replies: 1 comment 4 replies
-
|
Here are the docs for this: You can see the following:
I would recommend to establish the
e.g. verbose and descriptiveparam siteName string = 'ACU1-BRW-AOA-T5-fnDIS01'
param slotName string = 'dev'
resource webSite 'Microsoft.Web/sites@2021-02-01' existing = {
name: siteName
}
resource webSlot 'Microsoft.Web/sites/slots@2021-02-01' existing = {
name: slotName
parent: webSite
}
resource webSlotConfig 'Microsoft.Web/sites/slots/config@2021-02-01' existing = {
name: 'appsettings'
parent: webSlot
}
output config object = webSlotConfig.list()
output properties object = webSlotConfig.list().properties
output appInsightsKey string = webSlotConfig.list().properties['APPINSIGHTS_INSTRUMENTATIONKEY']
output AppSettings array = items(webSlotConfig.list().properties)same again, terse versionparam siteName string = 'ACU1-BRW-AOA-T5-fnDIS01'
param slotName string = 'dev'
resource webSlotConfig 'Microsoft.Web/sites/slots/config@2021-02-01' existing = {
name: '${siteName}/${slotName}/appsettings'
}
output config object = webSlotConfig.list()
output properties object = webSlotConfig.list().properties
output appInsightsKey string = webSlotConfig.list().properties['APPINSIGHTS_INSTRUMENTATIONKEY']
output AppSettings array = items(webSlotConfig.list().properties) |
Beta Was this translation helpful? Give feedback.
4 replies
-
|
Thanks! That's perfect and makes more sense now |
Beta Was this translation helpful? Give feedback.
-
|
Thanks for the confirmation on this, glad that it was helpful. Just for completeness ... Here is a 3rd param siteName string = 'ACU1-BRW-AOA-T5-fnDIS01'
param slotName string = 'dev'
resource webSite 'Microsoft.Web/sites@2021-02-01' existing = {
name: siteName
resource webSlot 'slots@2021-02-01' existing = {
name: slotName
resource webSlotConfig 'config@2021-02-01' existing = {
name: 'appsettings'
}
}
}
output config object = webSite::webSlot::webSlotConfig.list()
output properties object = webSite::webSlot::webSlotConfig.list().properties
output appInsightsKey string = webSite::webSlot::webSlotConfig.list().properties['APPINSIGHTS_INSTRUMENTATIONKEY']
output AppSettings array = items(webSite::webSlot::webSlotConfig.list().properties)Personally I don't mind the nesting of resources, that allows you to leave out the Preferably, I would like it, if there was a way to simply access: Maybe if there was only 1 output, this would seem cleaner... Or if we could assign the resource to a variable, then use that to call the method this is not supported:var slot = webSite::webSlot::webSlotConfig
output config object = slot.list()
output properties object = slot.list().properties
output appInsightsKey string = slot.list().properties['APPINSIGHTS_INSTRUMENTATIONKEY']
output AppSettings array = items(slot.list().properties) |
Beta Was this translation helpful? Give feedback.
-
|
Adding for follow up on the above syntax that is not supported, there is no indication that it will not work, the following exception is thrown. |
Beta Was this translation helpful? Give feedback.
-
|
moved the unhandled exception to: #5449 |
Beta Was this translation helpful? Give feedback.
Answer selected by
nick5454
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment
Here are the docs for this:
https://docs.microsoft.com/en-us/azure/azure-resource-manager/bicep/bicep-functions-resource#implementations
You can see the following:
I would recommend to establish the
existingresource reference first, then you can use that to call the list() function.e.g.
verbose and descriptive