build.gradle

plugins {
    id 'com.android.application'
    id 'org.jetbrains.kotlin.android'
    id 'com.google.gms.google-services'
}

android {
    compileSdk rootProject.ext.androidConfig.compileSdk

    dataBinding {
        enabled = true
    }
    defaultConfig {
        minSdk rootProject.ext.androidConfig.minSdk
        targetSdk rootProject.ext.androidConfig.targetSdk
        applicationId rootProject.ext.applicationId.app
        versionCode rootProject.ext.androidConfig.versionCode
        versionName rootProject.ext.androidConfig.versionName
        multiDexEnabled = true

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"

        javaCompileOptions {
            annotationProcessorOptions {
                arguments = [AROUTER_MODULE_NAME: project.getName()]
            }
        }
        ndk {
            rootProject.ext.androidConfig.abiFilters
        }
        flavorDimensions = ["offlinePush"]
        productFlavors {
            FCM {
                dimension "offlinePush"
            }
            Getui {
                dimension "offlinePush"
            }
        }
        //getui
        manifestPlaceholders = [
            GETUI_APPID    : "",
            XIAOMI_APP_ID  : "",
            XIAOMI_APP_KEY : "",
            MEIZU_APP_ID   : "",
            MEIZU_APP_KEY  : "",
            HUAWEI_APP_ID  : "",
            OPPO_APP_KEY   : "",
            OPPO_APP_SECRET: "",
            VIVO_APP_ID    : "",
            VIVO_APP_KEY   : "",
            HONOR_APP_ID   : "",
        ]
    }

    signingConfigs {
        release {
            keyAlias 'openim'
            keyPassword 'openim'
            storeFile file('./openim')
            storePassword 'openim'
        }
    }
    buildTypes {
        debug {
            signingConfig signingConfigs.release
        }
        release {
            signingConfig signingConfigs.release
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    buildFeatures {
        viewBinding true
    }
    lintOptions {
        checkReleaseBuilds false
        abortOnError false
    }
}

dependencies {
    implementation 'androidx.appcompat:appcompat:1.3.0'
    implementation 'com.google.android.material:material:1.4.0'
    implementation 'androidx.constraintlayout:constraintlayout:2.0.4'
    implementation 'androidx.legacy:legacy-support-v4:1.0.0'
    implementation "androidx.lifecycle:lifecycle-livedata-ktx:${rootProject.ext.versions.androidx_lifecycle}"
    testImplementation 'junit:junit:4.13.2'
    androidTestImplementation 'androidx.test.ext:junit:1.1.3'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.4.0'
    implementation 'androidx.multidex:multidex:2.0.1'

    implementation 'com.alibaba:arouter-api:1.5.2'
    annotationProcessor 'com.alibaba:arouter-compiler:1.5.2'
    implementation 'com.github.Wynsbin:VerificationCodeInputView:1.0.2'

    implementation 'com.github.czy1121:badgebutton:1.1.0'
    implementation 'com.hbb20:ccp:2.6.1'
    // getui
    GetuiImplementation 'com.getui:gtsdk:3.2.13.0'  //个推SDK
    GetuiImplementation 'com.getui:gtc:3.1.12.0'  //个推核心组件
    GetuiImplementation 'com.getui.opt:hwp:3.1.1'   // 华为
    GetuiImplementation 'com.getui.opt:xmp:3.3.0'   // 小米
    GetuiImplementation 'com.assist-v3:oppo:3.2.0'  // oppo
    GetuiImplementation 'com.assist-v3:vivo:3.1.0'  // vivo
    GetuiImplementation 'com.getui.opt:mzp:3.2.2'   // 魅族
    GetuiImplementation 'com.getui.opt:ups:3.0.3'   // ups，ups目前支持坚果，索尼，海信手机
    GetuiImplementation 'com.getui.opt:honor:3.2.0' // 荣耀
    GetuiImplementation 'com.huawei.hms:push:6.7.0.300'
    FCMImplementation(platform("com.google.firebase:firebase-bom:33.7.0"))
    FCMImplementation "com.google.firebase:firebase-messaging" // FCM
    FCMImplementation "com.google.firebase:firebase-analytics" // Optional for FCM
    //--------
    api project(':OUICore')
    if (!isModule) {
        implementation project(':OUIConversation')
        implementation project(':OUIGroup')
        implementation project(':OUIContact')
        implementation project(':OUICalling')
    }
}