Use GPUCompiler.lower_byval to avoid using the @codelet for inserting the preamble to fetch the arguments

[giordano]

CC: @maleadt

[maleadt]

using LLVM

function main()
    Context() do ctx
        mod = LLVM.Module("test")

        # dummy function
        ft = LLVM.FunctionType(LLVM.Int32Type(), [LLVM.Int32Type(), LLVM.Int32Type()])
        f = LLVM.Function(mod, "add", ft)
        IRBuilder() do builder
            bb = BasicBlock(f, "entry")
            position!(builder, bb)
            val = add!(builder, parameters(f)[1], parameters(f)[2])
            ret!(builder, val)
        end

        # new function
        new_ft = LLVM.FunctionType(LLVM.Int32Type())
        new_f = LLVM.Function(mod, "new_add", new_ft)
        value_map = Dict{LLVM.Value, LLVM.Value}()
        IRBuilder() do builder
            bb = BasicBlock(new_f, "parameters")
            position!(builder, bb)
            for (i, param) in enumerate(parameters(f))
                intr_ft = LLVM.FunctionType(value_type(param))
                intr = LLVM.Function(mod, "get_param_$i", intr_ft)
                new_param = call!(builder, intr_ft, intr)
                value_map[param] = new_param
            end

            # inline IR
            value_map[f] = new_f
            clone_into!(new_f, f; value_map,
                        changes=LLVM.API.LLVMCloneFunctionChangeTypeGlobalChanges)

            # fall through
            br!(builder, blocks(new_f)[2])
        end

        display(mod)
    end
    return
end

isinteractive() || main()

; ModuleID = 'test'
source_filename = "test"

define i32 @add(i32 %0, i32 %1) {
entry:
  %2 = add i32 %0, %1
  ret i32 %2
}

define i32 @new_add() {
parameters:
  %0 = call i32 @get_param_1()
  %1 = call i32 @get_param_2()
  br label %entry

entry:                                            ; preds = %parameters
  %2 = add i32 %0, %1
  ret i32 %2
}

declare i32 @get_param_1()

declare i32 @get_param_2()