build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven { url = 'https://maven.minecraftforge.net/' }
    }
    dependencies {
        classpath  group: 'net.minecraftforge.gradleutils', name: 'GradleUtils', version: '2.+', changing: true
    }
}

plugins {
    id 'java-library'
    id 'eclipse'
    id 'maven-publish'
    id 'org.cadixdev.licenser' version '0.6.1'
    id 'com.github.johnrengelman.shadow' version '7.0.0'
}
apply plugin: 'net.minecraftforge.gradleutils'

group 'xyz.bluspring'
version = gradleutils.getTagOffsetBranchVersion(null, 'master', 'HEAD')
println('Version: ' + version)

java.toolchain.languageVersion = JavaLanguageVersion.of(8)
compileJava.options.encoding = 'UTF-8'

ext {
    CHANGELOG = rootProject.file('build/changelog.txt')
    REPO = 'ForgeAutoRenamingTool'
    TITLE = 'Forge Auto Renaming Tool'
    MANIFEST = manifest{
        attributes('Main-Class': 'net.minecraftforge.fart.Main')
        attributes([
            'Specification-Title':      'ForgeAutoRenamingTool',
            'Specification-Vendor':     'Forge Development LLC',
            'Specification-Version':    gradleutils.gitInfo.tag,
            'Implementation-Title':     'SimpleInstaller',
            'Implementation-Version':   project.version,
            'Implementation-Vendor':    'Forge Development LLC'
        ] as LinkedHashMap, 'net/minecraftforge/fart/')
    }
    INITIAL_CHANGELOG_TAG = '0.1'
}

repositories {
    mavenCentral()
    maven { url = 'https://maven.minecraftforge.net/' }
}

test {
    useJUnitPlatform()
}

license {
    header = file('LICENSE-header.txt')
    ext.project = TITLE
}

dependencies {
    implementation 'net.sf.jopt-simple:jopt-simple:6.0-alpha-3'
    api 'net.minecraftforge:srgutils:0.5.1'
    implementation 'org.ow2.asm:asm:9.5'
    implementation 'org.ow2.asm:asm-commons:9.5'
    implementation 'org.ow2.asm:asm-tree:9.5'

    testImplementation(platform('org.junit:junit-bom:5.8.1'))
    testImplementation('org.junit.jupiter:junit-jupiter')
    testImplementation('org.powermock:powermock-core:2.0.9')

    compileOnly 'org.jetbrains:annotations:24.0.1'
}


test {
  useJUnitPlatform()
  testLogging {
    events 'passed', 'skipped', 'failed'
  }
}

java.withSourcesJar()

shadowJar {
    manifest.from(MANIFEST)
    minimize()

    def relocations = [
            'org.objectweb.asm',
            'net.minecraftforge.srgutils',
            'joptsimple'
    ]

    relocations.forEach {
        relocate it, "net.minecraftforge.fart.relocated.$it"
    }
}

assemble.dependsOn shadowJar

publishing {
    publications {
        mavenJava(MavenPublication) {
            groupId = "xyz.bluspring"
            artifactId = "AutoRenamingTool"

            from components.java
            pom {
                name = TITLE
                description = 'A tool that renames java bytecode elements.'
                url = "https://github.com/MinecraftForge/${REPO}"
                scm {
                    url = "https://github.com/MinecraftForge/${REPO}"
                    connection = "scm:git:git://github.com/MinecraftForge/${REPO}.git"
                    developerConnection = "scm:git:git@github.com:MinecraftForge/${REPO}.git"
                }
                issueManagement {
                    system = 'github'
                    url = "https://github.com/MinecraftForge/${REPO}/issues"
                }

                licenses {
                    license {
                        name = 'LGPLv2.1'
                        url = 'https://www.gnu.org/licenses/old-licenses/lgpl-2.1.txt'
                    }
                }

                developers {
                    developer {
                        id = 'LexManos'
                        name = 'LexManos'
                    }
                }
            }
        }
    }
    repositories {
        maven {
            url = uri("https://mvn.devos.one/snapshots")
            credentials {
                username = System.getenv()["MAVEN_USER"]
                password = System.getenv()["MAVEN_PASS"]
            }
        }
    }
}

changelog {
    fromTag INITIAL_CHANGELOG_TAG
}