build.gradle

plugins {
    id 'fabric-loom' version '1.9-SNAPSHOT'
    id 'maven-publish'
    id "fr.brouillard.oss.gradle.jgitver" version "0.9.1"
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
    mavenCentral()
    maven { url 'https://maven.terraformersmc.com/releases' }
}

loom {
    accessWidenerPath = file("src/main/resources/foxnap.accesswidener")
}

dependencies {

    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    // ModMenu support
    // modCompileOnly "com.terraformersmc:modmenu:${project.modmenu_version}"

    //SnakeYAML
    compileOnly "org.yaml:snakeyaml:${project.snakeyaml_version}"
    shadow(implementation("org.yaml:snakeyaml:${project.snakeyaml_version}"))

}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    // Minecraft 1.20.5 upwards uses Java 21.
    it.options.release = 21
}

java {
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}" }
    }
}

shadowJar {
    configurations = [project.configurations.shadow]
    archiveClassifier.set("dev")
    relocate "org.yaml", "{${project.maven_group}.${project.archivesBaseName}.shadow.org.yaml"
}

remapJar {
    dependsOn(shadowJar)
    inputFile = tasks.shadowJar.archiveFile
}

jgitver {
    useDirty = true
    useGitCommitID = true
    gitCommitIDLength = 8
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
    repositories {
        // Add repositories to publish to here.
        // Notice: This block does NOT have the same function as the block in the top level.
        // The repositories here will be used for publishing your artifact, not for
        // retrieving dependencies.
    }
}