build.gradle

import org.apache.tools.ant.filters.ReplaceTokens
apply plugin: 'java-library'
apply plugin: 'eclipse'

configurations {
    shade
    compile.extendsFrom shade
}

repositories {
	mavenCentral()
	jcenter()
   
	//Spigot
	maven {
		url 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/'
	}

	// Bungeecord
	maven {
		url "https://oss.sonatype.org/content/repositories/snapshots/"
	}
   
	//Skript
	maven {
		url 'https://raw.githubusercontent.com/bensku/mvn-repo/master'
	}
   
	//Jitpack
	maven {
		url 'https://jitpack.io'
	}

}

dependencies {

	// Nullable annotation
	implementation (group: 'org.eclipse.jdt', name: 'org.eclipse.jdt.annotation', version: '1.1.0')

	// Spigot
	implementation (group: 'org.spigotmc', name: 'spigot-api', version: '1.15.2-R0.1-SNAPSHOT')

	//Skript
	implementation (group: 'com.github.SkriptLang', name: 'Skript', version: '2.4-beta8') {
		transitive = false
	}

	//NoteblockAPI
	implementation (group: 'com.github.koca2000', name: 'NoteBlockAPI', version: '1.4.4')

	shade (group: 'org.json', name: 'json', version: '20190722')

}

processResources {
	filter ReplaceTokens, tokens: ["version": project.property("version")]
	from ('lang') {
        include '**/*'
        into 'lang/'
    }
	from (sourceSets.main.resources.srcDirs) {
		include '**/*.yml'
	}
}

jar {
    configurations.shade.each { dep ->
        from(project.zipTree(dep)){
            exclude 'META-INF', 'META-INF/**'
            exclude '**/*.yml'
        }
    }
}