-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathchimer
executable file
·4736 lines (4393 loc) · 184 KB
/
chimer
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#!/usr/bin/perl
# vi:set sw=2 ai sm:
# Copyright © 2021–2023 by Ambrose Li
=pod
=encoding utf8
=head1 NAME
chimer – Re-implementation of the Javascript chiming clocks in Perl
=head1 DESCRIPTION
The primary purpose of this script is to avoid running the two chiming clock pages as Firefox tabs,
because Firefox (and Chromium-based browsers) are now unfriendly to pages that primarily use audio for UI.
Firefox also leaks memory really fast so it's best to not keep Firefox running for long periods of time.
Eventually this script might provide a way to make the genmon script less CPU intensive.
=head1 INTERNALS
=cut
# see https://stackoverflow.com/questions/6162484/why-does-modern-perl-avoid-utf-8-by-default for these crazy hacks
# THERE ARE MORE CRAZY HACKS THERE FOR MORE COMPLEX PROJECTS!!
use v5.12; # minimal for unicode string feature
use v5.14; # //u modifier
use utf8;
open qw( :encoding(UTF-8) :std );
use charnames qw( :full :short );
use feature "unicode_strings";
use warnings qw( FATAL utf8 );
use Encode qw( encode decode );
#@ARGV = map { decode("UTF-8", $_) } @ARGV if grep /\P{ASCII}/ => @ARGV;
binmode STDIN, ':utf8';
binmode STDOUT, ':utf8';
binmode STDERR, ':utf8';
use strict;
use integer;
package Debug;
use Scalar::Util qw(blessed dualvar isdual readonly refaddr reftype tainted weaken isweak isvstring looks_like_number set_prototype);
sub lazy_sorter ($$) {
my($a, $b) = @_;
my $it;
if ($a =~ /^(.*?)(\d+(?:\.\d+)?)$/s) {
no integer;
my($a1, $a2) = ($1, $2);
if ($b =~ /^(.*?)(\d+(?:\.\d+)?)$/s) {
my($b1, $b2) = ($1, $2);
if ($a1 eq $b1 && $a1 =~ /q$/s) { # q0 = q4 therefore > q3
$it = ($a2 + 3)%4 <=> ($b2 + 3)%4;
} else {
$it = $a1 cmp $b1;
$it = $a2 <=> $b2 unless $it;
}
}
}
$it = $a cmp $b unless defined $it && $it;
return $it;
}
sub cvs ($) {
my($s) = @_;
my $it;
sub compute_size ($) {
my($s) = @_;
my $it;
if (!defined $s || !ref $s) {
$it = 1;
} elsif (ref $s eq 'ARRAY') {
for my $val (@$s) {
$it += compute_size($val);
}
} else { # hash or object
$it += 2 unless ref $s eq 'HASH';
for my $val (values %$s) {
$it += 1 + compute_size($val);
}
}
return $it;
}
sub format_scalar ($) {
my($it) = @_;
no integer;
if (!looks_like_number($it)) {
$it =~ s/([\\\(\)])/\\\1/sg;
$it =~ s/(\n)/\\n/sg;
$it = "($it)";
}
return $it;
}
sub format_as_name ($) {
my($s) = @_;
return $s =~ /^[-\.\w]+$/? "/$s": sprintf('%s cvn', cvs($s));
}
sub format_array_inner ($) {
my($s) = @_;
my $it;
if (compute_size($s) <= 12) { # cf. https://picolisp.com/wiki/?prettyPrint
$it = join(' ', map { cvs($_) } @$s);
} else {
my @s = @$s;
$it = cvs($s[0]) . "\n " . format_array_inner([@s[1..$#s]]);
}
return $it;
}
sub format_hash ($) {
my($s) = @_;
my @keys = sort { lazy_sorter($a, $b) } keys %$s;
my @size;
my $it;
for (my $i = $#keys; $i >= 0; $i -= 1) {
my $key = $keys[$i];
$size[$i] = compute_size($key) + compute_size($s->{$key});
$size[$i] += $size[$i + 1] if $i < $#keys;
}
for (my $i = 0; $i < @keys; $i += 1) {
my $key = $keys[$i];
$it .= ($size[$i] <= 12? ' ': "\n") if defined $it;
$it .= sprintf('%s %s', format_as_name $key, cvs($s->{$key}));
}
return "<<$it>>";
}
if (!defined $s) {
$it = 'null';
} elsif (ref $s eq 'ARRAY') {
$it = sprintf('[%s]', format_array_inner($s));
} elsif (ref $s eq 'HASH') {
$it = format_hash $s;
} elsif (!ref $s) {
$it = format_scalar $s;
} else { # object :-/
$it = sprintf '%s %s bless', format_hash $s, format_as_name ref $s;
}
return $it;
}
package Interpret_Melody_State;
no integer;
sub unit_beat {
my $self = shift;
$self->{'unit-beat'} = shift if @_;
return $self->{'unit-beat'};
}
sub tempo {
my $self = shift;
if (@_ && defined $_[0]) {
my($divisor, $beats_per_minute) = ref $_[0]? @{$_[0]}: @_;
$self->{'tempo'} = [$divisor, $beats_per_minute];
$self->unit_beat(($divisor*60)/(4*$beats_per_minute));
}
return wantarray? @{$self->{'tempo'}}: $self->{'tempo'};
}
sub relative_p {
my $self = shift;
$self->{'relative-p'} = shift if @_;
return $self->{'relative-p'};
}
sub drummode_p {
my $self = shift;
$self->{'drummode-p'} = shift if @_;
return $self->{'drummode-p'};
}
sub home_position {
my $self = shift;
$self->{'home-position'} = shift if @_;
return $self->{'home-position'};
}
sub repeat_start {
my $self = shift;
$self->{'repeat-start'} = shift if @_;
return $self->{'repeat-start'};
}
sub repeat_count {
my $self = shift;
$self->{'repeat-count'} = shift if @_;
return $self->{'repeat-count'};
}
sub repeat_stacklevel {
my $self = shift;
$self->{'repeat-stacklevel'} = shift if @_;
return $self->{'repeat-stacklevel'};
}
sub stacklevel {
my $self = shift;
return scalar @{$self->{'stack'}};
}
sub transpose {
my $self = shift;
$self->{'transpose'} = shift if @_; # FIXME?
return $self->{'transpose'};
}
sub new {
my $class = shift;
my $self = {};
bless $self, $class;
$self->unit_beat(1);
$self->relative_p(0);
$self->drummode_p(0);
$self->transpose(0);
$self->{'stack'} = [];
return $self;
}
sub gsave {
my $self = shift;
my $tempo = $self->tempo();
my $unit_beat = $self->unit_beat();
my $relative_p = $self->relative_p();
my $drummode_p = $self->drummode_p();
my $home_position = $self->home_position();
my $transpose = $self->transpose();
my $repeat_stacklevel = $self->repeat_stacklevel();
my $repeat_start = $self->repeat_start();
my $repeat_count = $self->repeat_count();
push @{$self->{'stack'}}, [$tempo, $unit_beat, $relative_p, $drummode_p, $home_position, $transpose,
$repeat_stacklevel, $repeat_start, $repeat_count];
}
sub grestore {
my $self = shift;
if (@{$self->{'stack'}}) {
my ($tempo, $unit_beat, $relative_p, $drummode_p, $home_position, $transpose,
$repeat_stacklevel, $repeat_start, $repeat_count)
= @{ pop @{$self->{'stack'}} };
$self->tempo ($tempo); # tempo must be restored first because setting it changes unit_beat
$self->unit_beat ($unit_beat);
$self->relative_p ($relative_p);
$self->drummode_p ($drummode_p);
$self->home_position ($home_position);
$self->transpose ($transpose);
$self->repeat_stacklevel ($repeat_stacklevel);
$self->repeat_start ($repeat_start);
$self->repeat_count ($repeat_count);
} else {
my $comment = sprintf(' (context: %s)', Debug::cvs($1)) if @_ && $_[0] =~ /^(.[^\n]*)/s;
die "grestore called but stack is empty$comment";
}
}
package Latency;
no integer;
use Time::HiRes;
sub MAX_LATENCIES_REMEMBERED () { 32 }
sub MAX_ERRORS_REMEMBERED () { 64 }
sub get_cpu_count () {
state $it;
my $input = '/proc/cpuinfo';
if (!defined $it && open(INPUT, '<', $input)) { # probably not Linux if we can't open it
for (;;) {
my $s = scalar <INPUT>;
last unless defined $s;
$it += 1 if $s =~ /^processor\s*:/s; # don't grep for "cpu cores" because some archs don't do that
}
close INPUT;
}
return $it;
}
sub get_loadavg () {
my $it;
my $input = '/proc/loadavg';
if (open(INPUT, '<', $input)) { # probably not Linux if we can't open it
my $s = scalar <INPUT>;
no integer;
$it = $1 + 0 if $s =~ /^(\d+\.\d+)\s/s;
close INPUT;
}
return $it;
}
sub register_error {
my $self = shift;
my($method, $delta) = @_;
$self->{'errors'}->{$method} = [] unless defined $self->{'errors'}->{$method};
push @{$self->{'errors'}->{$method}}, $delta;
shift @{$self->{'errors'}->{$method}} while scalar @{$self->{'errors'}->{$method}} > MAX_ERRORS_REMEMBERED;
}
sub remember {
my $self = shift;
my($latency, $tag) = @_;
my $node = {
'latency' => $latency,
't' => Time::HiRes::time,
};
$node->{'tag'} = $tag if defined $tag;
my $loadavg = get_loadavg;
if (defined $loadavg) {
$node->{'loadavg'} = $loadavg;
}
if (defined $self->{'predictions'}) {
foreach my $method (keys %{$self->{'predictions'}}) {
$self->register_error($method, $latency - $self->{'predictions'}->{$method});
}
$self->{'predictions'} = undef;
}
push @{$self->{'latencies'}}, $node;
shift @{$self->{'latencies'}} while scalar @{$self->{'latencies'}} > MAX_LATENCIES_REMEMBERED;
}
sub has_usable_measurements_p {
my $self = shift;
my $loadavg = get_loadavg;
my $it;
if (defined $loadavg) {
for my $latency (@{$self->{'latencies'}}) {
$it = 1 if abs($loadavg - $latency->{'loadavg'}) < 5; # XXX
last if defined $it;
}
$it = 0 unless defined $it;
} else {
# We have no way to tell. Just say yes.
$it = '0 but true';
}
return $it;
}
sub summation (@) {
my(@x) = @_;
my $it = 0;
foreach my $x_i (@x) {
$it += $x_i;
}
return $it;
}
sub error_estimate {
my $self = shift;
my($method) = @_;
my $deltas = $self->{'errors'}->{$method} if defined $self->{'errors'}->{$method};
return defined $deltas && @$deltas? summation(map { abs $_ } @$deltas)/scalar(@$deltas): undef;
}
sub predict_via_exponential_curve_fitting (\@$$) {
my($latencies, $loadavg, $t) = @_;
my $it;
if (@$latencies > 2 && defined $loadavg) {
no integer;
# Assume latency is exponentially related to loadavg
my($a, $b);
my $f = sub { my($x) = @_; $a * exp($b * $x) }; # log f = $b * $x + log($a)
# But simplify the approximation using log f (cf. p. 429 in my numerical methods textbook)
# not because the simplication is sound but because my numerical skills are not up to par
my $m = @$latencies;
my @x = map { $_->{'loadavg'} } @$latencies;
my @y = map { $_->{'latency'} } @$latencies;
my @i = 0..($m - 1);
my $denominator = ($m * summation(map { $x[$_]**2 } @i) - summation(@x)**2);
if ($denominator) {
$b = ($m * summation(map { $x[$_]*$y[$_] } @i) - summation(@x) * summation(@y)) / $denominator;
$a = (summation(@x) * summation(@y) - summation(map { $x[$_] * $y[$_] } @i) * summation(@x)) / $denominator;
$a = exp($a);
$it = &$f($loadavg);
}
}
return $it;
}
sub predict_via_polynomial_curve_fitting (\@$$) {
my($latencies, $loadavg, $t) = @_;
my $it;
if (@$latencies > 2 && defined $loadavg) {
no integer;
# Assume latency is quadratically related to loadavg
my($a, $b);
my $f = sub { my($x) = @_; $a * $x + $b };
my $m = @$latencies;
my @x = map { $_->{'loadavg'} } @$latencies;
my @y = map { $_->{'latency'} } @$latencies;
my @i = 0..($m - 1);
my $denominator = ($m * summation(map { $x[$_]**2 } @i) - summation(@x)**2);
if ($denominator) {
$a = ($m * summation(map { $x[$_]*$y[$_] } @i) - summation(@x) * summation(@y)) / $denominator;
$b = (summation(@x) * summation(@y) - summation(map { $x[$_] * $y[$_] } @i) * summation(@x)) / $denominator;
$it = &$f($loadavg);
}
}
return $it;
}
sub predict_via_averaging (\@$$) {
my($latencies, $loadavg, $t) = @_;
my $it;
if (@$latencies) {
no integer;
my $m = @$latencies;
my @y = map { $_->{'latency'} } @$latencies;
$it = summation(@y)/$m;
}
return $it;
}
sub predict_via_weighted_averaging (\@$$) {
my($latencies, $loadavg, $t) = @_;
my $it;
if (@$latencies && defined $loadavg) {
no integer;
state $k = 2**0.125;
my $m = @$latencies;
my @y = map { $_->{'latency'} * 2**($loadavg - $_->{'loadavg'}) } @$latencies;
$it = summation(@y)/$m;
}
return $it;
}
sub predict_from_loadavg {
my $self = shift;
my($loadavg) = @_;
my $prediction_method;
my $it;
my $t = Time::HiRes::time;
my @latencies = @{$self->{'latencies'}};
my %candidates;
# Calculate candidates predictions
# Exponential and polynomial sound like good ideas, but they actually give wildly inaccurate predictions
#$candidates{'exponential curve fitting'} = predict_via_exponential_curve_fitting(@latencies, $loadavg, $t);
#$candidates{'polynomial curve fitting'} = predict_via_polynomial_curve_fitting(@latencies, $loadavg, $t);
$candidates{'weighted-averaging'} = predict_via_weighted_averaging(@latencies, $loadavg, $t);
$candidates{'averaging'} = predict_via_averaging(@latencies, $loadavg, $t);
# Remove candidates that returned no results
for my $method (keys %candidates) {
delete $candidates{$method} unless defined $candidates{$method};
}
# Remove candidates that look implausible
for my $method (keys %candidates) {
if ($method ne 'averaging' && $candidates{$method} > 15) {
Chimer::log_debug(sprintf 'implausible candidate %s from %s removed from consideration', Debug::cvs($candidates{$method}), $method)
if (defined $Chimer::verbose_p && $Chimer::verbose_p > 1) || (defined $Chimer::debug && $Chimer::debug > 1);
delete $candidates{$method};
}
}
Chimer::log_debug(sprintf 'remaining candidates: %s', Debug::cvs(\%candidates))
if (defined $Chimer::verbose_p && $Chimer::verbose_p > 1) || (defined $Chimer::debug && $Chimer::debug > 1);
# Choose "best" prediction from candidates
if (keys %candidates == 1) {
($prediction_method, $it) = %candidates;
Chimer::log_debug(sprintf 'prediction %s from %s used because it was the only candidate', Debug::cvs(\@latencies), $prediction_method)
if (defined $Chimer::verbose_p && $Chimer::verbose_p > 1) || (defined $Chimer::debug && $Chimer::debug > 1);
} elsif (%candidates) {
my @scores = sort { $a->{'error'} <=> $b->{'error'} } map { { 'method' => $_, 'error' => $self->error_estimate($_) } } keys %candidates;
$prediction_method = $scores[0]->{'method'};
$it = $candidates{$prediction_method};
Chimer::log_debug(sprintf 'prediction %s from %s used because it looks historically accurate', Debug::cvs(\@latencies), $prediction_method)
if (defined $Chimer::verbose_p && $Chimer::verbose_p > 1) || (defined $Chimer::debug && $Chimer::debug > 1);
} else {
Chimer::log_debug(sprintf 'insufficient data to predict latency from %s', Debug::cvs(\@latencies))
if (defined $Chimer::verbose_p && $Chimer::verbose_p > 1) || (defined $Chimer::debug && $Chimer::debug > 1);
}
$self->{'predictions'} = \%candidates;
return wantarray? ($it, $prediction_method): $it;
}
sub predict {
my $self = shift;
return $self->predict_from_loadavg(get_loadavg);
}
sub tag {
my $self = shift;
$self->{'tag'} = shift if @_;
return $self->{'tag'};
}
sub new {
my $class = shift;
my($latency, $tag) = @_;
my $self = {};
bless $self, $class;
$self->remember($latency, $tag) if defined $latency;
return $self;
}
package Synth;
use feature 'signatures';
no warnings 'experimental::signatures';
package Chime_Id;
use feature 'signatures';
no warnings 'experimental::signatures';
sub new ($class, $id = undef) {
my $self = {
'implementation' => [],
};
$self->{'id'} = $id if defined $id;
bless $self, $class;
return $self;
}
sub id ($self, $id = undef) {
my $it = $self;
if (defined $id) {
$self->{'id'} = $id;
} else {
$it = $self->{'id'};
}
return $it;
}
sub mode ($self, $mode = undef) {
my $it = $self;
if (defined $mode) {
$self->{'mode'} = $mode;
} else {
$it = $self->{'mode'};
}
return $it;
}
sub melody ($self, $melody = undef) {
my $it = $self;
if (defined $melody) {
$self->{'melody'} = $melody;
} else {
$it = $self->{'melody'};
}
return $it;
}
sub implementation ($self) {
return $self->{'implementation'};
}
sub count ($self) {
return scalar @{$self->implementation};
}
sub prepend ($self, $event) {
unshift @{$self->implementation}, $event;
return $self;
}
sub append ($self, $event) {
push @{$self->implementation}, $event;
return $self;
}
package Event_List;
use feature 'signatures';
no warnings 'experimental::signatures';
sub new ($class) {
my $self = {
'events' => [],
};
bless $self, $class;
return $self;
}
sub value ($self) {
return $self->{'events'};
}
sub count ($self) {
return scalar @{$self->value};
}
sub prepend ($self, $event) {
unshift @{$self->value}, $event;
return $self;
}
sub append ($self, $event) {
push @{$self->value}, $event;
return $self;
}
sub id ($self) {
return join(',', map { $_->id } @{$self->value});
}
sub t ($self) {
return $self->value->[0]->t if @{$self->value};
}
sub delay ($self) {
return $self->value->[0]->delay if @{$self->value};
}
sub type ($self) {
my $it;
for my $node (@{$self->value}) {
$it = $node->type if defined $node->type && $node->type !~ /^(?:pre|post)/;
last if defined $it;
}
return $it;
}
package Event;
use feature 'signatures';
no warnings 'experimental::signatures';
sub new ($class, $t, $delta, $id, $type, $comment = undef) {
my $self = {
't' => $t,
'delta' => $delta,
'id' => $id,
'type' => $type,
};
$self->{'comment'} = $comment if defined $comment;
$self->{'anticipating'} = -$delta if defined $delta && $delta < 0;
bless $self, $class;
return $self;
}
sub t ($self) {
return $self->{'t'} + $self->{'delta'};
}
sub id ($self) {
return $self->{'id'};
}
sub type ($self) {
return $self->{'type'};
}
sub hour ($self) {
return (localtime $self->t)[2];
}
sub minute ($self) {
return (localtime $self->t)[1];
}
sub delay ($self) {
return $self->{'delay'};
}
package Event::Quarter::Half;
use vars qw( @ISA @EXPORT @EXPORT_OK );
@ISA = qw(Event::Quarter Exporter);
use feature 'signatures';
no warnings 'experimental::signatures';
sub new ($class, $t, $delta, $half_quarter_number) {
$half_quarter_number = 0 if $half_quarter_number == 8;
my($id, $type);
my($sec, $min, $hour) = localtime $t;
my $hour12 = $hour%12;
$hour12 = 12 unless $hour12;
if ($delta == 0 && $half_quarter_number == 0) {
$id = "h$hour12";
$type = 'hour';
} elsif ($delta == 0 && $half_quarter_number == 4) {
$id = sprintf('halb%d', $hour12%12 + 1);
$type = 'half-hour';
} elsif ($delta < 0 && $half_quarter_number%2) {
$id = "e$half_quarter_number";
$type = 'half quarter';
} elsif ($delta < 0) {
$id = sprintf('q%d', $half_quarter_number/2);
$type = 'quarter';
} elsif ($delta > 0 && $half_quarter_number == 0) {
$id = "posth$hour12";
$type = 'post-quarter';
} elsif ($delta > 0 && $half_quarter_number == 4) {
$id = sprintf('posthalb%d', $hour12%12 + 1);
$type = 'post-quarter';
} else {
die "Event::Quarter::Half->new: Unhandled case delta = $delta, half_quarter_number = $half_quarter_number\n";
}
return new Event($t, $delta, $id, $type);
}
package Event::Quarter;
use vars qw( @ISA @EXPORT @EXPORT_OK );
@ISA = qw(Event Exporter);
use feature 'signatures';
no warnings 'experimental::signatures';
sub new ($class, $t, $delta, $quarter_number) {
return new Event::Quarter::Half($t, $delta, 2*$quarter_number);
}
package Event::Watch;
use vars qw( @ISA @EXPORT @EXPORT_OK );
@ISA = qw(Event Exporter);
use feature 'signatures';
no warnings 'experimental::signatures';
sub new ($class, $t, $watch_number, $subwatch_number) {
my $id = "w$watch_number.$subwatch_number";
return new Event($t, undef, $id, 'quarter');
}
package Chimer;
use POSIX;
use POSIX ":sys_wait_h"; # for nonblocking read
use DateTime;
use Time::HiRes; # overrides (qw) do not seem to work
use Expect::Simple;
no feature 'signatures';
use Exporter;
require Exporter;
use vars qw( @ISA @EXPORT @EXPORT_OK );
@ISA = qw(Exporter);
@EXPORT_OK = qw( $dow_re $dow_range_re %expressive_mark_to_midi_velocity );
use vars qw( @restart_cmd );
@restart_cmd = ($0, @ARGV); # save this because GetOpt will clear @ARGV
use vars qw( $user_agent );
$user_agent = 'Chiming clock';
use vars qw( $use_datetime_event_sunrise );
use vars qw( $use_datetime_astro_sunrise );
use vars qw( $use_astro_sunrise );
use vars qw( $sunrise_module );
use vars qw( $sunrise_module_version );
BEGIN {
if (eval { require DateTime::Event::Sunrise; }) {
$sunrise_module = 'DateTime::Event::Sunrise';
$sunrise_module_version = DateTime::Event::Sunrise->VERSION if defined DateTime::Event::Sunrise->VERSION;
$use_datetime_event_sunrise = 1;
} elsif (eval { require DateTime::Astro::Sunrise; }) {
$sunrise_module = 'DateTime::Astro::Sunrise';
$sunrise_module_version = DateTime::Astro::Sunrise->VERSION if defined DateTime::Astro::Sunrise->VERSION;
$use_datetime_astro_sunrise = 1;
} elsif (eval { require Astro::Sunrise; }) {
$sunrise_module = 'Astro::Sunrise';
$sunrise_module_version = Astro::Sunrise->VERSION if defined Astro::Sunrise->VERSION;
$use_astro_sunrise = 1;
} else {
die "Cannot find a usable Sunrise package";
}
}
use Getopt::Long;
use Data::Dumper;
use vars qw( $config );
use vars qw( $overrides );
use vars qw( $debug );
use vars qw( $no_cache_p $create_cache_p $test_p );
use vars qw( $latent_action );
use vars qw( $verbose_p );
use vars qw( $quit_p );
use vars qw( $enable_nonproportional_watches );
use vars qw( $enable_qing_quarters );
use vars qw( $coords );
use vars qw( $lat $lon );
use vars qw( $use_jack_p );
use vars qw( @sinks );
use vars qw( $synth );
use vars qw( %children );
use vars qw( %expected_latency );
use vars qw( $wood_note );
use vars qw( %instrument_name_to_channel_number );
use vars qw( %instrument_name_to_mf_velocity );
use vars qw( $fluidR3 );
$fluidR3 = '/usr/share/sounds/sf2/FluidR3_GM.sf2';
use vars qw( $beat_length );
$beat_length = 1;
use vars qw( $boottime );
$boottime = Time::HiRes::time;
use vars qw( $time_displacement );
sub current_time () { no integer; Time::HiRes::time + $time_displacement }
use vars qw( $basedir $datadir );
$basedir = $1 if $0 =~ /^(.*?)\/+[^\/]+$/;
$basedir =~ s/(?:^|\/+)bin$//;
$basedir = '.' if $basedir eq '';
$datadir = "$basedir/data";
# number of times we try sleeping for 1 second until we sleep until the target event
sub COUNTDOWN () { 5 } # things stablize after 2-3 times, we do 5 just in case (10 is overkill)
# number of seconds to sleep before we disconnect the synth - from observation this must be at least 6
sub SECONDS_BEFORE_DISCONNECT () { 7 }
sub MODE__SYSLINE () { 'sysline' }
sub MODE__CUCKOO () { 'cuckoo' }
sub MODE__CARILLON () { 'carillon' }
sub METHOD__SAMPLES () { 'samples' }
sub METHOD__SYNTH () { 'synth' }
sub MELODY__ABBEY () { 'abbey' }
sub MELODY__CAMBRIDGE () { 'cambridge' }
sub MELODY__CAMBRIDGE_RCC () { 'cambridge_rcc' }
sub MELODY__CANTERBURY () { 'canterbury' }
sub MELODY__GUILDFORD () { 'guildford' }
sub MELODY__MAGDALEN () { 'magdalen' }
sub MELODY__NEWCOLLEGE () { 'newcollege' }
sub MELODY__NORWICH () { 'norwich' }
sub MELODY__TINGTANG2A () { 'tingtang2a' }
sub MELODY__TINGTANG2B () { 'tingtang2b' }
sub MELODY__TINGTANG3A () { 'tingtang3a' }
sub MELODY__TINGTANG3B () { 'tingtang3b' }
sub MELODY__TINGTANG4 () { 'tingtang4' }
sub MELODY__TINGTANG5 () { 'tingtang5' }
sub MELODY__WESTMINSTER () { 'westminster' }
sub MELODY__WHITTINGTON () { 'whittington' }
sub MELODY__WHITTINGTON11 () { 'whittington11' }
sub MELODY__TORONTO () { 'toronto' }
use vars qw( $mode $method $melody );
$mode = MODE__CARILLON;
$method = METHOD__SAMPLES;
$melody = MELODY__WESTMINSTER;
use vars qw( %alias_to_canonical_instrument );
%alias_to_canonical_instrument = (
'Keyboard' => 'Piano',
'Carillon' => 'Bell',
'Chimes' => 'Church Bells',
);
use vars qw( %laisser_vibrer_p );
%laisser_vibrer_p = (
'Bell' => 1,
'Gong' => 1,
);
# night watch chime patterns
sub LONG_STRIKE () { 1.5 }
sub SHORT_STRIKE () { 0.5 }
sub GAP () { 2.5 }
# watch chime patterns: repetitions, pattern
# gap needs to be long enough to hear it, but short enough to not mistake it for a long strike. This is HARD
use vars qw( @watch_chime_pattern );
@watch_chime_pattern = ( # v. https://zh.wikipedia.org/wiki/打更 (q.v.)
[3, '— .' ],
[2, '. .' ],
[3, '— . .' ],
[4, '— . . .' ],
[5, '— . . . .' ],
);
use vars qw( @midi_number_to_note %note_to_midi_number );
@midi_number_to_note = (
'c0', 'c#0', 'd0', 'd#0', 'e0', 'f0', 'f#0', 'g0', 'g#0', 'a0', 'a#0', 'b0',
'c1', 'c#1', 'd1', 'd#1', 'e1', 'f1', 'f#1', 'g1', 'g#1', 'a1', 'a#1', 'b1',
'c2', 'c#2', 'd2', 'd#2', 'e2', 'f2', 'f#2', 'g2', 'g#2', 'a2', 'a#2', 'b2',
'c3', 'c#3', 'd3', 'd#3', 'e3', 'f3', 'f#3', 'g3', 'g#3', 'a3', 'a#3', 'b3',
'c4', 'c#4', 'd4', 'd#4', 'e4', 'f4', 'f#4', 'g4', 'g#4', 'a4', 'a#4', 'b4',
'c5', 'c#5', 'd5', 'd#5', 'e5', 'f5', 'f#5', 'g5', 'g#5', 'a5', 'a#5', 'b5',
'c6', 'c#6', 'd6', 'd#6', 'e6', 'f6', 'f#6', 'g6', 'g#6', 'a6', 'a#6', 'b6',
'c7', 'c#7', 'd7', 'd#7', 'e7', 'f7', 'f#7', 'g7', 'g#7', 'a7', 'a#7', 'b7',
'c8', 'c#8', 'd8', 'd#8', 'e8', 'f8', 'f#8', 'g8', 'g#8', 'a8', 'a#8', 'b8',
'c9', 'c#9', 'd9', 'd#9', 'e9', 'f9', 'f#9', 'g9', 'g#9', 'a9', 'a#9', 'b9',
);
%note_to_midi_number = map { $midi_number_to_note[$_] => $_ } 0..$#midi_number_to_note;
use vars qw( %gong_scale %chime_scale );
%gong_scale = (
'c4' => '582141__strangehorizon__g01-c-4-gong.wav',
'c#4' => '582140__strangehorizon__g02-c-4-gong.wav',
'd4' => '582139__strangehorizon__g03-d-4-gong.wav',
'd#4' => '582138__strangehorizon__g04-d-4-gong.wav',
'e4' => '582145__strangehorizon__g05-e-4-gong.wav',
'f4' => '582144__strangehorizon__g06-f-4-gong.wav',
'f#4' => '582143__strangehorizon__g07-f-4-gong.wav',
'g4' => '582142__strangehorizon__g08-g-4-gong.wav',
'g#4' => '582147__strangehorizon__g09-g-4-gong.wav',
'a4' => '582146__strangehorizon__g10-a-4-gong.wav',
'a#4' => '582156__strangehorizon__g11-a-4-gong.wav',
'b4' => '582155__strangehorizon__g12-b-4-gong.wav',
'c5' => '582154__strangehorizon__g13-c-5-gong.wav',
'c#5' => '582153__strangehorizon__g14-c-5-gong.wav',
'd5' => '582160__strangehorizon__g15-d-5-gong.wav',
'd#5' => '582159__strangehorizon__g16-d-5-gong.wav',
'e5' => '582158__strangehorizon__g17-e-5-gong.wav',
'f5' => '582157__strangehorizon__g18-f-5-gong.wav',
'f#5' => '582162__strangehorizon__g19-f-5-gong.wav',
'g5' => '582161__strangehorizon__g20-g-5-gong.wav',
);
%chime_scale = (
'c4' => 'chimes_C1.ogg',
'c#4' => 'chimes_C#1.ogg',
'd4' => 'chimes_D1.ogg',
'd#4' => 'chimes_D#1.ogg',
'e4' => 'chimes_E1.ogg',
'f4' => 'chimes_F1.ogg',
'f#4' => 'chimes_F#1.ogg',
'g4' => 'chimes_G1.ogg',
'g#4' => 'chimes_G#1.ogg',
'a4' => 'chimes_A1.ogg',
'a#4' => 'chimes_A#1.ogg',
'b4' => 'chimes_B1.ogg',
'c5' => 'chimes_C2.ogg',
'c#5' => 'chimes_C#2.ogg',
'd5' => 'chimes_D2.ogg',
'd#5' => 'chimes_D#2.ogg',
'e5' => 'chimes_E2.ogg',
'f5' => 'chimes_F2.ogg',
);
sub gensym () {
state $n;
return sprintf('g%d', $n++);
}
sub log_internal ($$;$$$) {
my($flag, $s, $prefix, $newline_p, $keep_p) = @_;
state $last_logged;
my $daemon_p = !-t STDERR;
$newline_p = 1 if $s =~ s/^\n+//s;
$newline_p = 0 unless defined $last_logged;
$newline_p = 1 if defined $last_logged && $last_logged->{'keep'};
$newline_p = 0 if $daemon_p;
my $cleol_p = !$daemon_p && !$newline_p;
$keep_p = 1 if $debug;
$prefix .= ': ' if defined $prefix && $prefix =~ /\S/s && $prefix !~ /: $/s;
chomp $s;
printf STDERR "%s%10.2f%s\t%s%s%s%s", ($newline_p? "\n": ''),
current_time, $flag, $prefix, $s, ($cleol_p? "\033[K": ''), ($daemon_p? "\n": "\r");
$last_logged->{'keep'} = $keep_p + 0;
}
sub log_input ($) { log_internal '<', $_[0] }
sub log_output ($) { log_internal '>', $_[0] }
sub log_comment ($) { log_internal '#', $_[0] }
sub log_debug ($) { log_internal '#', $_[0], 'DEBUG', 1, 1 }
sub log_info ($) { log_internal '#', $_[0], undef, 0, 1 }
sub log_error ($) { log_internal '#', $_[0], 'ERROR', 1, 1 }
sub log_warning ($) { log_internal '#', $_[0], 'WARNING', 1, 1 }
sub log_command (@) { log_debug 'running: '. join(' ', map { s/([\\"])/\\\1/sg if /\s/; /\s|^$/? "\"$_\"": $_ } @_) }
=pod
=head2 Chime melodies
Each chime melody is internally represented as an array of
B<[>I<midi note name>, I<time in seconds>, I<percentage volume>, I<instrument>B<]> entries
(I<instrument> can be undef),
but written as calls to I<define_event> which takes 3 parameters –
the identifier for the mode,
the identifier for the melody,
a string containing any definitions (in the form S<I<var> = I<some definition>>) –
plus a list of key-value pairs.
Valid keys are B<q1> for first-quarter chimes,
B<q2> for second-quarter chimes,
B<q3> for third-quarter chimes,
B<q0> for fourth-quarter chimes,
and B<h> for the hour strike.
As many definitions as needed can be included, but each definition I<must> be of the form of either of
=over
I<var> = B<\relative> I<pitch> B<{> I<melody> B<}>
I<var> = B<\drums> B<{> I<melody> B<}>
I<var> B<{> I<tempo or some other initialization> B<}>
=back
The values are written in LilyPond notation
(in either relative pitch or drum mode, optionally including note lengths and basic expressive marks),
described in