Topic: Синтаксический анализатор

[kupihleba]

Здесь проектирование синтаксического анализатора, обсуждение грамматики формул

[kupihleba]

Приближённая грамматика синтаксического анализатора:

<Root> :== <Expression> <Tail>
<Tail> :== <Cmp> <Expression> | Ɛ
<Cmp> :== <= | >= | ==
<Expression> :== <SubAdd> | <N> | <VF> | <Q> | string
<SubAdd> :== < + | - > <Expression>
<N> :== number <T '>
<T '> :== <T> | Ɛ
<T> :== <SubAdd> | <DivMul>
<DivMul> :== < * | / > <DMNext>
<DMNext> :== <N> | <VF> | <Q>
<VF> :== <Function> | <Variable>
<Function> :== var/func ( <Params> ) <T '>
<Variable> :== var/func <T '>
<Q> :== ( <Expression> ) <T '>
<Params> :== <Root> <More>   // FIX !!!
<More> :== , <Root> | Ɛ      // FIX !!!

[SimpleCreations]

Правильная грамматика

<Expression>         :== <Compared> <ComparedRest>
<ComparedRest>       :== <ComparisonOperator> <Compared> <ComparedRest> | ε
<ComparisonOperator> :== "=" | "<" | ">" | "<=" | ">="
<Compared>           :== <Term> <Terms>
<Terms>              :== "-" <Term> <Terms> | "+" <Term> <Terms> | ε
<Term>               :== <Factor> <Factors>
<Factors>            :== "*" <Factor> <Factors> | "/" <Factor> <Factors> | ε
<Factor>             :== NUMBER | STRING | "TRUE" | "FALSE" | <Identifiable> | "(" <Expression> ")" | "-" <Factor>
<Identifiable>       :== IDENTIFIER <Call>
<Call>               :== "(" <Arguments> ")" | ε
<Arguments>          :== <Expression> <ArgumentsRest> | ε
<ArgumentsRest>      :== "," <Expression> <ArgumentsRest> | ε

[Mazdaywik]

Неправильная грамматика.

<Compared>           :== <Term> <Terms>
<Terms>              :== "-" <Term> <Terms> | "+" <Term> <Terms> | ε
<Term>               :== <Factor> <Factors>
<Factors>            :== "*" <Factor> <Factors> | "/" <Factor> <Factors> | ε

Эти правила нам дают такие странные арифметические выражения как -/3*2+*3. А вот нормальное 1+2*3 описать ею нельзя.

[Mazdaywik]

<Expression>         :== <Compared> <ComparedRest>
<ComparedRest>       :== <ComparisonOperator> <Compared> <ComparedRest> | ε

Я правильно понял, что вы хотите как в Питоне: x < y < z подразумевается x < y and y < z?

[SimpleCreations]

Я правильно понял, что вы хотите как в Питоне: x < y < z подразумевается x < y and y < z?

Нет. Такая запись синтаксически корректна, но вернёт ошибку времени выполнения.
Она означает (x < y) < z; первая функция < вернёт значение типа boolean, а вторая создаст ошибку несовместимости типов (boolean и number).
Например, в JS в такой записи при выполнении второго оператора < результат выполнения первого приведётся к 0/1.

Неправильная грамматика.

Я попробовал составить дерево разбора данных выражений. Корректное выражение удалось разобрать, ваш контрпример даёт синтаксическую ошибку. Пожалуйста, укажите на ошибку в моих рассуждениях: http://puu.sh/x9J8D/08c6b301b8.jpg

[Mazdaywik]

Да, у меня ошибка, у вас всё правильно.

[SimpleCreations]

Обновление грамматики. Добавление поддержки диапазонов (Range).

<Expression>         :== <Compared> <ComparedRest>
<ComparedRest>       :== <ComparisonOperator> <Compared> <ComparedRest> | ε
<ComparisonOperator> :== "=" | "<" | ">" | "<=" | ">="
<Compared>           :== <Term> <Terms>
<Terms>              :== "-" <Term> <Terms> | "+" <Term> <Terms> | ε
<Term>               :== <Factor> <Factors>
<Factors>            :== "*" <Factor> <Factors> | "/" <Factor> <Factors> | ε
<Factor>             :== NUMBER | STRING | "TRUE" | "FALSE" | <Identifiable> | "(" <Expression> ")" | "-" <Factor>
<Identifiable>       :== IDENTIFIER <CallOrSpan>
<CallOrSpan>         :== "(" <Arguments> ")" | ":" IDENTIFIER | ε
<Arguments>          :== <Expression> <ArgumentsRest> | ε
<ArgumentsRest>      :== "," <Expression> <ArgumentsRest> | ε