CMakeLists.txt

# SPDX-Identifier: MIT
cmake_minimum_required(VERSION 3.14)

project(
  "stdlib-example"
  LANGUAGES "Fortran"
  VERSION "0.1"
)

# Follow GNU conventions for installing directories
include(GNUInstallDirs)

# General configuration information
add_subdirectory("config")

if(NOT TARGET "fortran_stdlib::fortran_stdlib")
  find_package("fortran_stdlib" REQUIRED)
endif()

# Collect source of the project
add_subdirectory("src")

# Collect source of the application
add_subdirectory("app")

# Export targets for other projects
add_library("${PROJECT_NAME}" INTERFACE)
target_link_libraries("${PROJECT_NAME}" INTERFACE "${PROJECT_NAME}-lib")
install(
  TARGETS
  "${PROJECT_NAME}"
  EXPORT
  "${PROJECT_NAME}-targets"
  LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
  ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
)

# Install exported targets
install(
  EXPORT "${PROJECT_NAME}-targets"
  NAMESPACE
  "${PROJECT_NAME}::"
  DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}"
)

# Package license files
install(
  FILES
  "LICENSE"
  DESTINATION "${CMAKE_INSTALL_DATADIR}/licenses/${PROJECT_NAME}"
)

# Include test suite
enable_testing()
add_subdirectory("test")