build.gradle

buildscript {
    ext {
        ebeanVersion = '13.25.2'
        sqliteVersion = '3.44.1.0'
        javalinVersion = '5.6.3'

        lombokVersion = '1.18.30'
        gsonVersion = '2.10.1'
        logbackVersion = '1.4.14'
        commonsLangVersion = '3.14.0'
        javaFakerVersion = '1.0.2'

        grpcVersion = '1.60.0'
        protobufVersion = '3.21.12'

        protobufPluginVersion = '0.9.4'
        versionPluginVersion = '0.50.0'
    }
}

plugins {
    id 'idea'
    id 'java'
    id('io.ebean') version "${ebeanVersion}"
    id('com.github.ben-manes.versions') version "${versionPluginVersion}"
    id('com.google.protobuf') version "${protobufPluginVersion}"
}

group = 'cl.ucn.disc.as'
version = '0.0.5'

repositories {
    mavenLocal()
    mavenCentral()
}

protobuf {
    protoc {
        artifact = "com.google.protobuf:protoc:${protobufVersion}"
    }
    clean {
        delete generatedFilesBaseDir
    }
    plugins {
        grpc {
            artifact = "io.grpc:protoc-gen-grpc-java:${grpcVersion}"
        }
    }
    generateProtoTasks {
        all()*.plugins {
            grpc {}
        }
    }
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

compileJava {
    options.encoding = 'UTF-8'
}

dependencies {
    // junit
    testImplementation platform('org.junit:junit-bom:5.10.1')
    testImplementation 'org.junit.jupiter:junit-jupiter'

    // lombok
    testCompileOnly "org.projectlombok:lombok:${lombokVersion}"
    testAnnotationProcessor "org.projectlombok:lombok:${lombokVersion}"

    // ebean
    testImplementation "io.ebean:ebean-test:${ebeanVersion}"

    // ebean
    implementation "io.ebean:ebean:${ebeanVersion}"
    implementation "io.ebean:ebean-ddl-generator:${ebeanVersion}"
    annotationProcessor "io.ebean:querybean-generator:${ebeanVersion}"

    // database
    implementation "org.xerial:sqlite-jdbc:${sqliteVersion}"
    // implementation 'com.h2database:h2:2.2.220'

    // json
    implementation "com.google.code.gson:gson:${gsonVersion}"

    // web: javalin
    implementation "io.javalin:javalin:${javalinVersion}"
    implementation "com.aayushatharva.brotli4j:brotli4j:1.13.0"
    implementation "com.nixxcode.jvmbrotli:jvmbrotli:0.2.0"

    // lombok
    compileOnly "org.projectlombok:lombok:${lombokVersion}"
    annotationProcessor "org.projectlombok:lombok:${lombokVersion}"

    // logger
    implementation "ch.qos.logback:logback-core:${logbackVersion}"
    implementation "ch.qos.logback:logback-classic:${logbackVersion}"

    // commons-lang3
    implementation "org.apache.commons:commons-lang3:${commonsLangVersion}"

    // data faker
    implementation "com.github.javafaker:javafaker:${javaFakerVersion}"

    // gRPC
    runtimeOnly "io.grpc:grpc-netty-shaded:${grpcVersion}"
    implementation "io.grpc:grpc-protobuf:${grpcVersion}"
    implementation "io.grpc:grpc-stub:${grpcVersion}"
    implementation 'javax.annotation:javax.annotation-api:1.3.2'

}

ebean {
    debugLevel = 9 //0 - 9
}

test {
    useJUnitPlatform()
    testLogging.showStandardStreams = true
    testLogging.exceptionFormat = 'full'
}

// Inform IntelliJ  about the generated code.
idea {
    module {
        sourceDirs += file("src/generated/main/java")
        sourceDirs += file("src/generated/main/grpc")
    }
}