build.gradle

apply plugin: 'java'
apply plugin: 'war'


version = '0.2.1'
description = 'LBU-BB-Legacy'
group = 'uk.ac.leedsbeckett'

def bbhandle = 'bblegacy'
def bbname = 'LBU-BB-Legacy'
def bbdescription = 'LBU BB Legacy'
def vendorid = 'LBU'
def vendorname = 'Leeds Beckett University'
def vendordescription = 'Leeds Beckett University'
def vendorurl = 'http://www.leedsbeckett.ac.uk/'


// Ensure compatible with Java 11 even if using newer compiler.
java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(11))
    }
}

tasks.withType(JavaCompile) {
    options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
}


clean {
    delete "${buildDir}/webappconfig"
}

war.doFirst {
  copy {
    from "src/main/webappconfig"
    into "${buildDir}/webappconfig"
    expand([
     bbhandle: bbhandle,
     bbname: bbname,
     version: version,
     vendorid: vendorid,
     vendorname: vendorname,
     vendordescription: vendordescription,
     vendorurl: vendorurl,
     description: bbdescription
    ])
  }
}
war {
  webInf { from "${buildDir}/webappconfig" }
}

repositories {
    jcenter()
    maven {
      url "https://maven.blackboard.com/content/repositories/releases/"
    }    
}

dependencies {
    compileOnly "javax.servlet:javax.servlet-api:3.1.0"
    compileOnly "blackboard.platform:bb-platform:3900.0.0"
    compileOnly "blackboard.platform:xsscore:3900.0.0"
    
    implementation 'org.apache.commons:commons-text:1.9'
    implementation 'org.apache.commons:commons-compress:1.20'    
    implementation 'commons-fileupload:commons-fileupload:1.4'

    implementation 'commons-io:commons-io:2.8.0'
    testImplementation 'junit:junit:4.12'
}