build.gradle

plugins {
    id 'java-library'
    id 'java'
    id 'maven-publish'
    id 'signing'
    id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'
    id 'com.palantir.git-version' version '3.1.0'
    id 'org.jetbrains.kotlin.jvm' version '2.0.21'
}

apply from: 'hooks.gradle'

repositories {
    mavenCentral()
    mavenLocal()
}

group = 'io.github.lsd-consulting'
version = gitVersion().replaceAll("^v", "")
logger.lifecycle("Version:$version")

ext {
    junitJupiter = '5.11.3'
}

wrapper {
    gradleVersion = "8.7"
}

allprojects {
    plugins.withId('java') {
        dependencies {
            implementation 'io.github.lsd-consulting:lsd-core:7.0.59'
            implementation 'io.github.lsd-consulting:lsd-formatting-library:4.0.62'

            testImplementation 'org.assertj:assertj-core:3.26.3'
            testImplementation 'io.mockk:mockk-jvm:1.13.13'
            testImplementation "org.junit.jupiter:junit-jupiter:$junitJupiter"
        }
    }
}
subprojects {
    plugins.withId('java-library') {

        tasks.register('sourcesJar', Jar) {
            dependsOn classes
            archiveClassifier = 'sources'
            from sourceSets.main.allSource
        }

        tasks.register('javadocJar', Jar) {
            archiveClassifier = 'javadoc'
            from javadoc
        }

        apply plugin: 'maven-publish'
        publishing {
            publications {
                "$project.name"(MavenPublication) {
                    groupId = 'io.github.lsd-consulting'
                    artifactId project.name
                    version = "${gitVersion().replaceAll("^v", "")}"

                    from components.java
                    artifact sourcesJar
                    artifact javadocJar

                    pom {
                        name = "lsd-interceptors"
                        description = "Provides various interceptors to capture events for the lsd-core library to generate sequence diagrams"
                        url = 'https://github.com/lsd-consulting/lsd-interceptors.git'
                        licenses {
                            license {
                                name = "MIT License"
                                url = "https://github.com/lsd-consulting/lsd-interceptors/blob/main/LICENSE.txt"
                                distribution = "repo"
                            }
                        }
                        developers {
                            developer {
                                name = "Nick"
                                email = "nicholas.mcdowall@gmail.com"
                                organization = 'NKM IT Solutions Ltd'
                                organizationUrl = 'https://github.com/nickmcdowall'
                            }
                            developer {
                                name = "Lukasz"
                                email = "lukasz.gryzbon@gmail.com"
                                organization = 'Integreety Ltd.'
                                organizationUrl = 'https://github.com/integreety'
                            }
                        }
                        scm {
                            url = "https://github.com/lsd-consulting/lsd-interceptors.git"
                        }
                    }
                    repositories {
                        maven {
                            name = 'sonatype'
                            url = "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/"
                            credentials(PasswordCredentials)
                        }
                    }
                }
            }
        }
    }
}

nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://s01.oss.sonatype.org/service/local/"))
            snapshotRepositoryUrl.set(uri("https://s01.oss.sonatype.org/content/repositories/snapshots/"))
        }
    }
}

signing {
    if (project.findProperty("signingKey")) {
        // Use in-memory ascii-armored keys
        def signingKey = findProperty("signingKey")
        def signingPassword = findProperty("signingPassword")
        useInMemoryPgpKeys(signingKey, signingPassword)
        sign publishing.publications
    } else {
        // Use signing properties in ~/.gradle/gradle.properties
        sign publishing.publications
    }
}