build.gradle

buildscript {
  ext.kotlinVersion = '1.5.30'
  repositories {
    google()
    mavenCentral()
  }
  dependencies {
    classpath 'com.android.tools.build:gradle:4.1.2'
    classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
    classpath 'com.vanniktech:gradle-android-junit-jacoco-plugin:0.16.0'
  }
}

allprojects {
  repositories {
    google()
    mavenCentral()
  }
}

subprojects { project ->
  group = GROUP
  version = VERSION_NAME

  apply plugin: 'checkstyle'
  checkstyle{
    configFile file("${rootDir}/config/checkstyle/checkstyle.xml")
    toolVersion = '8.6'
  }

  task checkstyle(type: Checkstyle) {
    source 'src/main/java'
    ignoreFailures false
    showViolations true
    include '**/*.java'
    classpath = files()
  }

  afterEvaluate {
    if (project.tasks.findByName('check')) {
      check.dependsOn('checkstyle')
    }
  }
  apply plugin: 'com.vanniktech.android.junit.jacoco'
}

task clean(type: Delete) {
  delete rootProject.buildDir
}


ext {
  minSdkVersion = 8
  targetSdkVersion = 29
  compileSdkVersion = 29
  buildToolsVersion = '29.0.3'
}

ext.deps = [
    junit             : 'junit:junit:4.12',
    truth             : 'com.google.truth:truth:0.28',
    robolectric       : 'org.robolectric:robolectric:3.3',
    mockito           : "org.mockito:mockito-core:2.19.0",
    json              : "org.json:json:20160810",
    supportAnnotations: 'androidx.annotation:annotation:1.0.0',
    kotlin            : "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlinVersion",
]