build.gradle

buildscript {
    repositories {
        jcenter()
    }
}

plugins {
    id "com.jfrog.bintray" version "1.8.3"
}

allprojects {
    repositories {
        jcenter()
    }
    apply plugin: 'java'
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'
}

dependencies {
    api group:'org.eclipse.jetty.websocket', name:'websocket-client', version:'9.4.32.v20200930'
    implementation group:'org.apache.commons', name:'commons-lang3', version:'3.9'
    implementation group:'ch.qos.logback', name:'logback-classic', version:'1.2.3'
    implementation group:'com.fasterxml.jackson.core', name:'jackson-databind', version:'2.9.8'
    implementation group:'com.fasterxml.jackson.dataformat', name:'jackson-dataformat-yaml', version:'2.9.8'
    implementation group:'javax.inject', name:'javax.inject', version:'1'
    implementation group:'org.bouncycastle', name:'bcprov-jdk15on', version:'1.66'
    implementation group:'org.bouncycastle', name:'bcpkix-jdk15on', version:'1.66'
    implementation group:'org.apache.httpcomponents', name:'httpclient', version:'4.5.12'
    implementation group:'junit', name:'junit', version:'4.13'
}

String binGroupId = 'it.unimore.dipi'
String binLibName = 'openness-connector'
String binVer = '0.0.5'

group = binGroupId
version = binVer

// Create the pom configuration:
def pomConfig = {
    licenses {
        license {
            name "The Apache Software License, Version 3.0"
            url "http://www.apache.org/licenses/LICENSE-3.0.txt"
            distribution "repo"
        }
    }
    developers {
        developer {
            id "smarianimore"
            name "Stefano Mariani"
            email "stefano.mariani@unimore.it"
        }
    }

    scm {
        url "https://gitlab.com/SteMore/openness-connector.git"
    }
}

publishing {
    publications {
        MyPublication(MavenPublication) {
            from components.java
            groupId binGroupId
            artifactId binLibName
            version binVer
            pom.withXml {
                def root = asNode()
                root.appendNode('description', 'Openness connector library')
                root.appendNode('name', binLibName)
                root.appendNode('url', 'https://gitlab.com/SteMore/openness-connector.git')
                root.children().last() + pomConfig
            }
        }
    }
}

bintray {
    user = project.hasProperty('bintrayUser') ? project.property('bintrayUser') : System.getenv('BINTRAY_USER')
    key = project.hasProperty('bintrayApiKey') ? project.property('bintrayApiKey') : System.getenv('BINTRAY_API_KEY')
    configurations = ['archives']
    publications = ['MyPublication']
    pkg {
        repo = binLibName
        name = binLibName
        licenses = ['AGPL-V3']
        vcsUrl = 'https://gitlab.com/SteMore/openness-connector.git'
        version {
            name = binVer
            released  = new Date()
        }
    }
}