-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathLesHouches.m
2444 lines (1720 loc) · 45.7 KB
/
LesHouches.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
(* ::Title:: *)
(*LesHouches*)
(* ::Subsubsection:: *)
(*metadata*)
(* :Title: LesHouches *)
(* :Author: Andrew Miller <amiller@physics.umn.edu> *)
(* :Context: LesHouches` *)
(* :Version: 0.1.0 *)
(* :Date: 2016-11-01 *)
(* :Mathematica Version: 10.2 *)
(* :Copyright: (c) 2016 Andrew Miller *)
(* ::Title::GrayLevel[0]:: *)
(*context LesHouches`*)
(* ::Subsubsection::GrayLevel[0]::Closed:: *)
(*begin package context*)
BeginPackage @ "LesHouches`";
(* ::Section:: *)
(*package information*)
(* ::Subsubsection::Closed:: *)
(*general*)
LesHouches`Developer`$Version = "0.1.0 (November 1, 2016)";
LesHouches`Developer`$VersionNumber = StringReplace[LesHouches`Developer`$Version, "." ~~ Except["."] .. ~~ EndOfString :> ""];
LesHouches`Developer`$ReleaseNumber = StringSplit[LesHouches`Developer`$Version, {" ", "."}][[3]];
LesHouches`Developer`$CreationDate := DateObject @ Last @ StringSplit[LesHouches`Developer`$Version, {"(", ")"}]
LesHouches`Developer`$PackageDirectory = DirectoryName @ $InputFileName;
(* ::Section:: *)
(*usage messages*)
(* ::Subsection:: *)
(*(un)installation*)
(* ::Subsubsection::Closed:: *)
(*InstallLesHouches*)
InstallLesHouches::usage = "InstallLesHouches[\"component\"] installs the components associated with the LesHouches package to the $UserBaseDirectory file tree.
InstallLesHouches[\"Components\"] gives a list of the installable components.";
(* ::Subsubsection::Closed:: *)
(*UninstallLesHouches*)
UninstallLesHouches::usage = "UninstallLesHouches[\"component\"] uninstalls the components associated with the LesHouches package from the $UserBaseDirectory file tree.";
(* ::Subsection:: *)
(*data objects*)
(* ::Subsubsection::Closed:: *)
(*LesHouchesDataObject*)
LesHouchesDataObject::usage = "LesHouchesDataObject[\[Ellipsis]] is a container for block, decay table, and cross section table data."
(* ::Chapter:: *)
(*context LesHouches`Private`*)
(* ::Subsubsection::GrayLevel[0]::Closed:: *)
(*begin private context*)
Begin @ "`Private`";
(* ::Section:: *)
(*utilities*)
(* ::Subsection:: *)
(*string parsers*)
(* ::Subsubsection::Closed:: *)
(*string output stream method*)
If[
! MemberQ[$OutputStreamMethods, "String"],
DefineOutputStreamMethod[
"String",
{
"ConstructorFunction" -> Function[
{streamname, isAppend, caller, opts},
With[
{state = Unique @ "StringOutputStream"},
state @ "string" ="";
state @ "pos" = 0;
{True,state}
]
],
"CloseFunction" -> Function[state, ClearAll @ state],
"StreamPositionFunction" -> Function[state, {state @ "pos", state}],
"WriteFunction" -> Function[
{state, bytes},
state @ "pos" += Length @ bytes;
state @ "string" = StringJoin[state @ "string", FromCharacterCode @ bytes];
{Length @ bytes, state}
],
"OptionChangesFunction" -> Function[
{state, opts},
{Append[opts, "String" -> state @ "string"], state}
]
}
]
]
(* ::Subsubsection::Closed:: *)
(*stringLineJoin*)
stringLineJoin[s : {__String}] := Module[
{
stream = OpenWrite["string", FormatType -> OutputForm, Method -> "String"]
},
Scan[WriteLine[stream, #] &, s];
With[
{
string = "String" /. Rest[Method /. Options @ stream]
},
Close @ stream;
string
]
]
(* ::Section:: *)
(*(un)installation*)
(* ::Subsection:: *)
(*installation*)
(* ::Subsubsection:: *)
(*iInstallLesHouches*)
(* ::Subsubsubsection::Closed:: *)
(*info*)
Options @ iInstallLesHouches = Options @ CopyFile;
(* ::Subsubsubsection::Closed:: *)
(*format mappings*)
iInstallLesHouches["FormatMappings", opts : OptionsPattern[]] := With[
{
$aliasTargetFile = FileNameJoin[
{
$UserBaseDirectory,
"SystemFiles",
"Formats",
"FormatMappings.m"
}
],
$aliasSourceFile = FileNameJoin[
{
LesHouches`Developer`$PackageDirectory,
"Formats",
"FormatMappings.m"
}
]
},
If[
! FileExistsQ @ $aliasTargetFile,
If[
! DirectoryQ[DirectoryName @ $aliasTargetFile],
Echo[
"Directory " ~~ DirectoryName @ $aliasTargetFile ~~ " created.",
"InstallLesHouches: ",
Style[#, "SR", FontColor -> Gray] &
];
CreateDirectory[Directory @ $aliasTargetFile]
];
CopyFile[
$aliasSourceFile,
$aliasTargetFile,
Evaluate@FilterRules[{opts}, Options@CopyFile]
];
Echo[
"Copied " ~~ $aliasSourceFile ~~ " to " ~~ $aliasTargetFile ~~ ".",
"InstallLesHouches: ",
Style[#, "SR", FontColor -> Gray] &
],
Export[
$aliasTargetFile,
StringJoin[
StringReplace[
ToString[
Union[Import[$aliasTargetFile, "Package"], Import[$aliasSourceFile, "Package"]],
InputForm
],
{"," -> ",\n", "{" -> "{\n ", "}" -> "\n}"}
]
],
"Text"
];
Echo[
"Added LesHouches format aliases to " ~~ $aliasTargetFile ~~ ".",
"InstallLesHouches: ",
Style[#, "SR", FontColor -> Gray] &
]
]
]
(* ::Subsubsubsection::Closed:: *)
(*converters*)
iInstallLesHouches["Converters", opts : OptionsPattern[]] := With[
{
$formatTargetDirectory = FileNameJoin[
{
$UserBaseDirectory,
"SystemFiles",
"Formats",
"LesHouches"
}
],
$formatSourceDirectory = FileNameJoin[
{
LesHouches`Developer`$PackageDirectory,
"Formats",
"LesHouches"
}
]
},
If[
!DirectoryQ @ $formatTargetDirectory,
Echo[
"Directory " ~~ $formatTargetDirectory ~~ " created.",
"InstallLesHouches: ",
Style[#, "SR", FontColor -> Gray] &
];
CreateDirectory @ $formatTargetDirectory
];
Export[
FileNameJoin @ {$formatTargetDirectory, "Import.m"},
StringReplace[
Import[FileNameJoin @ {$formatSourceDirectory, "Import.template"}, "Text"],
"SourcesPath" -> FileNameJoin @ {LesHouches`Developer`$PackageDirectory, "Kernel", "init.m"}
],
"Text"
];
Echo[
"Exported LesHouches import rules to " ~~ FileNameJoin @ {$formatTargetDirectory, "Import.m"} ~~ ".",
"InstallLesHouches: ",
Style[#, "SR", FontColor -> Gray] &
];
iInstallLesHouches["FormatMappings", opts];
]
(* ::Subsubsection::Closed:: *)
(*InstallLesHouches*)
Options @ InstallLesHouches = Options @ iInstallLesHouches;
SyntaxInformation @ InstallLesHouches = {
"ArgumentsPattern" -> {_, OptionsPattern[]},
"OptionNames" -> Keys @ Options @ InstallLesHouches
};
InstallLesHouches["Components"] = {"Converters"};
InstallLesHouches[
comp_String /; MemberQ[InstallLesHouches @ "Components", comp],
opts : OptionsPattern[]
] := iInstallLesHouches[comp, opts];
(* ::Subsection:: *)
(*uninstallation*)
(* ::Subsubsection:: *)
(*iUninstallLesHouches*)
(* ::Subsubsubsection::Closed:: *)
(*format mappings*)
iUninstallLesHouches["FormatMappings"] := With[
{
$aliasTargetFile = FileNameJoin[
{
$UserBaseDirectory,
"SystemFiles",
"Formats",
"FormatMappings.m"
}
],
$aliasSourceFile = FileNameJoin[
{
LesHouches`Developer`$PackageDirectory,
"Formats",
"FormatMappings.m"
}
]
},
If[
! FileExistsQ @ $aliasTargetFile,
With[
{
formats = Complement[Import[$aliasTargetFile, "Package"], Import[$aliasSourceFile, "Package"]]
},
If[
Length @ formats > 0,
Export[
$aliasTargetFile,
StringJoin[
StringReplace[
ToString[formats, InputForm],
{"," -> ",\n", "{" -> "{\n ", "}" -> "\n}"}
]
],
"Text"
],
DeleteFile @ $aliasTargetFile
]
];
Echo[
"Removed LesHouches format aliases from " ~~ $aliasTargetFile ~~ ".",
"UninstallLesHouches: ",
Style[#, "SR", FontColor -> Gray] &
]
]
]
(* ::Subsubsubsection::Closed:: *)
(*converters*)
iUninstallLesHouches["Converters"] := With[
{
$formatTargetDirectory = FileNameJoin[
{
$UserBaseDirectory,
"SystemFiles",
"Formats",
"LesHouches"
}
],
$formatSourceDirectory = FileNameJoin[
{
LesHouches`Developer`$PackageDirectory,
"Formats",
"LesHouches"
}
]
},
DeleteDirectory[$formatTargetDirectory, DeleteContents -> True];
Echo[
"Removed LesHouches format directory " ~~ $formatTargetDirectory,
"UninstallLesHouches: ",
Style[#, "SR", FontColor -> Gray] &
];
iUninstallLesHouches @ "FormatMappings";
]
(* ::Subsubsection::Closed:: *)
(*UninstallLesHouches*)
SyntaxInformation @ UninstallLesHouches = {"ArgumentsPattern" -> {_, OptionsPattern[]}};
UninstallLesHouches["Components"] = {"Converters"};
UninstallLesHouches[
comp_String /; MemberQ[InstallLesHouches @ "Components", comp]
] := iUninstallLesHouches[comp];
(* ::Section:: *)
(*data objects*)
(* ::Subsection:: *)
(*data object properties and methods*)
(* ::Subsubsection::Closed:: *)
(*block*)
$dataObjectProperties @ "Block" = {
"Name",
"RenormalizationScale",
"Description"
};
$dataObjectMethods @ "Block" = {
"RawData",
"Data",
"Dataset",
"Table",
"Keys",
"Values",
"Descriptions",
"Rules",
"Matrix",
"SparseArray",
"HeaderPrintFormatString",
"DataPrintFormatString",
"Plaintext"
};
(* ::Subsubsection::Closed:: *)
(*decay*)
$dataObjectProperties @ "Decay" = {
"InitialState",
"TotalWidth",
"Description"
};
$dataObjectMethods @ "Decay" = {
"RawData",
"Data",
"Dataset",
"Table",
"FinalStates",
"BranchingRatios",
"Descriptions",
"Rules",
"HeaderPrintFormatString",
"DataPrintFormatString",
"Plaintext"
};
(* ::Subsubsection::Closed:: *)
(*xsection*)
$dataObjectProperties @ "XSection" = {
"CenterOfMassEnergy",
"InitialStates",
"FinalStates",
"ProcessRule",
"Description"
};
$dataObjectMethods @ "XSection" = {
"RawData",
"Data",
"Dataset",
"Table",
"HeaderPrintFormatString",
"DataPrintFormatString",
"Plaintext"
};
(* ::Subsection:: *)
(*data object type tests*)
(* ::Subsubsection::Closed:: *)
(*blockDataQ*)
blockDataQ = And[
AssociationQ @ #,
ContainsOnly[Keys @ #, Join[$dataObjectProperties @ "Block", {"Data"}]],
KeyExistsQ[#, "Name"],
If[
KeyExistsQ[#, "Data"],
And[
MatchQ[# @ "Data", {__Association}],
AllTrue[
Keys @ Merge[# @ "Data", Identity],
StringMatchQ["Key" | "Value" | "Description"]
]
],
True
]
] &
(* ::Subsubsection::Closed:: *)
(*decayDataQ*)
decayDataQ = And[
AssociationQ @ #,
ContainsOnly[Keys @ #, Join[$dataObjectProperties @ "Decay", {"Data"}]],
KeyExistsQ[#, "InitialState"],
KeyExistsQ[#, "TotalWidth"],
If[
KeyExistsQ[#, "Data"],
And[
MatchQ[# @ "Data", {__Association}],
AllTrue[
Keys @ Merge[# @ "Data", Identity],
StringMatchQ["BranchingRatio" | "FinalStates" | "Description"]
]
],
True
]
] &
(* ::Subsubsection::Closed:: *)
(*xsectionDataQ*)
xsectionDataQ = And[
AssociationQ @ #,
ContainsOnly[Keys @ #, Join[$dataObjectProperties @ "XSection", {"Data"}]],
KeyExistsQ[#, "ProcessRule"],
KeyExistsQ[#, "CenterOfMassEnergy"],
If[
KeyExistsQ[#, "Data"],
And[
MatchQ[# @ "Data", {__Association}],
AllTrue[
Keys @ Merge[# @ "Data", Identity],
Alternatives[
"ScaleScheme",
"QCDOrder",
"EWOrder",
"KappaFactorization",
"KappaRenormalization",
"PartonDistributionFunctionID",
"CrossSection",
"ProgramName",
"ProgramVersion",
"Description"
] // StringMatchQ
]
],
True
]
] &
(* ::Subsection:: *)
(*iLesHouchesDataObject*)
(* ::Subsubsubsection::Closed:: *)
(*info*)
Options @ iLesHouchesDataObject = {};
(* ::Subsubsection:: *)
(*properties*)
(* ::Subsubsubsection::Closed:: *)
(*"Properties"*)
iLesHouchesDataObject[
structure : ("Block" | "Decay" | "XSection"),
assoc_,
opts : OptionsPattern[]
]["Properties"] := Intersection[Keys @ assoc, Join[{"Structure"}, $dataObjectProperties @ structure]]
(* ::Subsubsubsection::Closed:: *)
(*"Structure"*)
iLesHouchesDataObject[
structure : ("Block" | "Decay" | "XSection"),
assoc_,
opts : OptionsPattern[]
]["Structure"] := structure
(* ::Subsubsubsection::Closed:: *)
(*all other properties*)
iLesHouchesDataObject[
structure : ("Block" | "Decay" | "XSection"),
assoc_,
opts : OptionsPattern[]
][prop_String] := Lookup[assoc, prop, Missing["NotAvailable", prop]]
(* ::Subsubsection:: *)
(*methods*)
(* ::Subsubsubsection::Closed:: *)
(*"Methods"*)
iLesHouchesDataObject[
structure : ("Block" | "Decay" | "XSection"),
assoc_,
opts : OptionsPattern[]
]["Methods"] := $dataObjectMethods @ structure
(* ::Subsubsubsection::Closed:: *)
(*"RawData"*)
iLesHouchesDataObject[
structure : ("Block" | "Decay" | "XSection"),
assoc_,
opts : OptionsPattern[]
]["RawData"] := assoc
(* ::Subsubsubsection::Closed:: *)
(*"Data"*)
iLesHouchesDataObject[
structure : ("Block" | "Decay" | "XSection"),
assoc_,
opts : OptionsPattern[]
]["Data"] := Lookup[assoc, "Data", Missing["NotAvailable", "Data"]]
iLesHouchesDataObject[
structure : ("Block" | "Decay" | "XSection"),
assoc_,
opts : OptionsPattern[]
]["Data", f_] := With[
{
data = iLesHouchesDataObject[structure, assoc, opts]["Data"]
},
If[
! MissingQ @ data,
f @ data,
data
]
]
(* ::Subsubsubsection::Closed:: *)
(*"Dataset"*)
iLesHouchesDataObject[
structure : ("Block" | "Decay" | "XSection"),
assoc_,
opts : OptionsPattern[]
]["Dataset"] := With[
{
data = iLesHouchesDataObject[structure, assoc, opts]["Data"]
},
If[
! MissingQ @ data,
Dataset @ data,
Missing["NotAvailable", "Dataset"]
]
]
iLesHouchesDataObject[
structure : ("Block" | "Decay" | "XSection"),
assoc_,
opts : OptionsPattern[]
]["Dataset", args__] := With[
{
dataset = iLesHouchesDataObject[structure, assoc, opts]["Dataset"]
},
If[
! MissingQ @ dataset,
dataset @ args,
dataset
]
]
(* ::Subsubsubsection::Closed:: *)
(*"Table"*)
iLesHouchesDataObject[
"Block",
assoc_? blockDataQ,
opts : OptionsPattern[]
]["Table"] := With[
{
data = iLesHouchesDataObject["Block", assoc, opts]["Data"]
},
If[
! MissingQ @ data,
Lookup[data, {"Key", "Value", "Description"}, Missing @ "NotAvailable"],
Missing["NotAvailable", "Table"]
]
]
iLesHouchesDataObject[
structure : ("Decay" | "XSection"),
assoc_? blockDataQ,
opts : OptionsPattern[]
]["Table"] := With[
{
data = iLesHouchesDataObject[structure, assoc, opts]["Data"]
},
If[
! MissingQ @ data,
Lookup[data, Keys @ Merge[data, Identity], Missing @ "NotAvailable"],
Missing["NotAvailable", "Table"]
]
]
iLesHouchesDataObject[
structure : ("Block" | "Decay" | "XSection"),
assoc_,
opts : OptionsPattern[]
]["Table", args : Repeated[_, {1, 2}]] := With[
{
table = iLesHouchesDataObject[structure, assoc, opts]["Table"]
},
If[
! MissingQ @ table,
table[[args]],
table
]
]
(* ::Subsubsubsection::Closed:: *)
(*"Keys"*)
iLesHouchesDataObject[
"Block",
assoc_? blockDataQ,
opts : OptionsPattern[]
]["Keys"] := With[
{
data = iLesHouchesDataObject["Block", assoc, opts]["Data"]
},
If[
! MissingQ @ data,
Lookup[data, "Key", Nothing],
Missing["NotAvailable", "Keys"]
]
]
iLesHouchesDataObject[
"Block",
assoc_? blockDataQ,
opts : OptionsPattern[]
]["Keys", args__] := With[
{
keys = iLesHouchesDataObject["Block", assoc, opts]["Keys"]
},
If[
! MissingQ @ keys,
keys[[args]],
keys
]
]
(* ::Subsubsubsection::Closed:: *)
(*"Values"*)
iLesHouchesDataObject[
"Block",
assoc_? blockDataQ,
opts : OptionsPattern[]
]["Values"] := With[
{
data = iLesHouchesDataObject["Block", assoc, opts]["Data"]
},
If[
! MissingQ @ data,
Lookup[data, "Value", Nothing],
Missing["NotAvailable", "Values"]
]
]
iLesHouchesDataObject[
"Block",
assoc_? blockDataQ,
opts : OptionsPattern[]
]["Values", args__] := With[
{
values = iLesHouchesDataObject["Block", assoc, opts]["Values"]
},
If[
! MissingQ @ values,
values[[args]],
values
]
]
(* ::Subsubsubsection::Closed:: *)
(*"FinalStates"*)
iLesHouchesDataObject[
"Decay",
assoc_? decayDataQ,
opts : OptionsPattern[]
]["FinalStates"] := With[
{
data = iLesHouchesDataObject["Decay", assoc, opts]["Data"]
},
If[
! MissingQ @ data,
Lookup[data, "FinalStates", Nothing],
Missing["NotAvailable", "FinalStates"]
]
]
iLesHouchesDataObject[
"Decay",
assoc_? decayDataQ,
opts : OptionsPattern[]
]["FinalStates", args__] := With[
{
states = iLesHouchesDataObject["Decay", assoc, opts]["FinalStates"]
},
If[
! MissingQ @ states,
states[[args]],
states
]
]
(* ::Subsubsubsection::Closed:: *)
(*"BranchingRatios"*)
iLesHouchesDataObject[
"Decay",
assoc_? decayDataQ,
opts : OptionsPattern[]
]["BranchingRatios"] := With[
{
data = iLesHouchesDataObject["Decay", assoc, opts]["Data"]
},
If[
! MissingQ @ data,
Lookup[data, "BranchingRatios", Nothing],
Missing["NotAvailable", "BranchingRatios"]
]
]
iLesHouchesDataObject[
"Decay",
assoc_? decayDataQ,
opts : OptionsPattern[]
]["BranchingRatios", args__] := With[
{
bratios = iLesHouchesDataObject["Decay", assoc, opts]["BranchingRatios"]
},
If[
! MissingQ @ bratios,
bratios[[args]],
bratios
]