Building v2 apps on NixOS #1156

ianmjones · 2022-02-15T22:50:42Z

ianmjones
Feb 15, 2022

I've been able to create a simple Nix derivation that might eventually be the base for submitting for inclusion in nixpkgs, and therefore also NixOS.

{ lib
, buildGoModule
, fetchFromGitHub
, pkg-config
, gtk3
, webkitgtk
}:

buildGoModule rec {
  pname = "wails";
  version = "f923a43";

  src = fetchFromGitHub
    {
      owner = "wailsapp";
      repo = pname;
      rev = "${version}";
      sha256 = "RXt4/DPOtC99Z2PDdRrnJQ0rRAXZWePkHk90TBNZFvI=";
    } + "/v2";

  vendorSha256 = "qPMVsvud2L7hpXUOfYYMiO32JXff8ZZC34EsxFoSJ0g=";

  proxyVendor = true;

  subPackages = [ "cmd/wails" ];

  nativeBuildInputs = [
    pkg-config
  ];

  propagatedBuildInputs = [
    gtk3
    webkitgtk
  ];

  doCheck = true;

  ldflags = [
    "-s"
    "-w"
  ];

  meta = with lib; {
    description = "Build applications using Go + HTML + CSS + JS";
    homepage = "https://wails.io";
    license = licenses.mit;
    maintainers = with maintainers; [ ianmjones ];
    platforms = platforms.linux;
  };
}

After building that derivation I can use it to initialize a project with ~/Projects/nixpkgs/result/bin/wails init -ide goland -t svelte -n wails-test.

After updating the go.mod to point to my local checkout of the wails source as per https://wails.io/docs/guides/bleeding-edge, I can successfully build with ~/Projects/nixpkgs/result/bin/wails build -tags exp, but only as long as I first nix-shell with the following shell.nix:

with import <nixpkgs> { };
stdenv.mkDerivation {
  name = "env";
  nativeBuildInputs = [
    pkg-config
  ];
  buildInputs = [
    gtk3
    webkitgtk
  ];
}

The above nix-shell makes sure PKG_CONFIG_PATH is set correctly for the dynamically linked libraries, and also works when running the app:

However, it does not always work, sometimes the window flashes and goes away leaving a fatal error. And when it does work, when I quit the app it too leaves the same critical error like follows:

[nix-shell:~/Projects/wails-test]$ build/bin/wails-test
Overriding existing handler for signal 10. Set JSC_SIGNAL_FOR_GC if you want WebKit to use a different signal

(wails-test:445973): Gtk-CRITICAL **: 22:06:42.399: gtk_box_pack: assertion 'GTK_IS_WIDGET (child)' failed
fatal error: unexpected signal during runtime execution
[signal SIGSEGV: segmentation violation code=0x80 addr=0x0 pc=0x7f6fde50eea5]

runtime stack:
runtime.throw({0x673176, 0x12e8278})
	/nix/store/76qbr3hy9adncz7j149wx9s34s0namyw-go-1.17.6/share/go/src/runtime/panic.go:1198 +0x71
runtime.sigpanic()
	/nix/store/76qbr3hy9adncz7j149wx9s34s0namyw-go-1.17.6/share/go/src/runtime/signal_unix.go:719 +0x396

goroutine 1 [syscall]:
runtime.cgocall(0x5fe510, 0xc0001d5dd8)
	/nix/store/76qbr3hy9adncz7j149wx9s34s0namyw-go-1.17.6/share/go/src/runtime/cgocall.go:156 +0x5c fp=0xc0001d5db0 sp=0xc0001d5d78 pc=0x40b0fc
github.com/wailsapp/wails/v2/internal/frontend/desktop/linux._Cfunc_GTKWIDGET(0x12e8270)
	_cgo_gotypes.go:493 +0x49 fp=0xc0001d5dd8 sp=0xc0001d5db0 pc=0x5ead89
github.com/wailsapp/wails/v2/internal/frontend/desktop/linux.(*Window).asGTKWidget.func1(0xc0001d5e28)
	/home/ian/Projects/wails/v2/internal/frontend/desktop/linux/window.go:573 +0x3b fp=0xc0001d5e10 sp=0xc0001d5dd8 pc=0x5f317b
github.com/wailsapp/wails/v2/internal/frontend/desktop/linux.(*Window).asGTKWidget(0x12e8270)
	/home/ian/Projects/wails/v2/internal/frontend/desktop/linux/window.go:573 +0x19 fp=0xc0001d5e28 sp=0xc0001d5e10 pc=0x5f3119
github.com/wailsapp/wails/v2/internal/frontend/desktop/linux.(*Window).Destroy.func2(0xc0001d5e80)
	/home/ian/Projects/wails/v2/internal/frontend/desktop/linux/window.go:604 +0x19 fp=0xc0001d5e60 sp=0xc0001d5e28 pc=0x5f3659
github.com/wailsapp/wails/v2/internal/frontend/desktop/linux.(*Window).Destroy(0xc0001c8230)
	/home/ian/Projects/wails/v2/internal/frontend/desktop/linux/window.go:604 +0x28 fp=0xc0001d5e80 sp=0xc0001d5e60 pc=0x5f3608
github.com/wailsapp/wails/v2/internal/frontend/desktop/linux.(*Window).Run(0xc0001c8230)
	/home/ian/Projects/wails/v2/internal/frontend/desktop/linux/window.go:703 +0xa5 fp=0xc0001d5e98 sp=0xc0001d5e80 pc=0x5f4705
github.com/wailsapp/wails/v2/internal/frontend/desktop/linux.(*Frontend).Run(0xc0001c81c0, {0x6d9d00, 0xc00011ff80})
	/home/ian/Projects/wails/v2/internal/frontend/desktop/linux/frontend.go:130 +0xbd fp=0xc0001d5ed8 sp=0xc0001d5e98 pc=0x5eec1d
github.com/wailsapp/wails/v2/internal/appng.(*App).Run(0xc000202000)
	/home/ian/Projects/wails/v2/internal/appng/app_production.go:37 +0x31 fp=0xc0001d5f10 sp=0xc0001d5ed8 pc=0x5fc451
github.com/wailsapp/wails/v2.Run(0xc0000001a0)
	/home/ian/Projects/wails/v2/wails.go:24 +0x33 fp=0xc0001d5f28 sp=0xc0001d5f10 pc=0x5fcbb3
main.main()
	/home/ian/Projects/wails-test/main.go:26 +0x3af fp=0xc0001d5f80 sp=0xc0001d5f28 pc=0x5fd02f
runtime.main()
	/nix/store/76qbr3hy9adncz7j149wx9s34s0namyw-go-1.17.6/share/go/src/runtime/proc.go:255 +0x227 fp=0xc0001d5fe0 sp=0xc0001d5f80 pc=0x43d107
runtime.goexit()
	/nix/store/76qbr3hy9adncz7j149wx9s34s0namyw-go-1.17.6/share/go/src/runtime/asm_amd64.s:1581 +0x1 fp=0xc0001d5fe8 sp=0xc0001d5fe0 pc=0x469ca1

goroutine 19 [chan receive]:
github.com/wailsapp/wails/v2/internal/frontend/desktop/linux.(*Frontend).startMessageProcessor(0x0)
	/home/ian/Projects/wails/v2/internal/frontend/desktop/linux/frontend.go:111 +0x59
created by github.com/wailsapp/wails/v2/internal/frontend/desktop/linux.NewFrontend
	/home/ian/Projects/wails/v2/internal/frontend/desktop/linux/frontend.go:96 +0x367

goroutine 20 [chan receive]:
github.com/wailsapp/wails/v2/internal/frontend/desktop/linux.(*Frontend).startRequestProcessor(0x0)
	/home/ian/Projects/wails/v2/internal/frontend/desktop/linux/frontend.go:277 +0x5a
created by github.com/wailsapp/wails/v2/internal/frontend/desktop/linux.NewFrontend
	/home/ian/Projects/wails/v2/internal/frontend/desktop/linux/frontend.go:97 +0x3a9

Does anyone know how I can stop that fatal error?

@diogox, any ideas? And would you like to be added to the maintainers list if/when I submit a PR to nixpkgs for Wails v2 once it officially supports Linux (or is in stable-ish beta)?

Answered by ianmjones

Mar 6, 2022

I've submitted a PR to nixpkgs, hopefully it'll pass review and test. 🤞

NixOS/nixpkgs#162947

View full answer

leaanthony · 2022-02-16T09:35:48Z

leaanthony
Feb 16, 2022
Maintainer

Hi Ian! Thanks for this amazing work. It would be great to get this working.
Looking at the gtk references in the stack trace, there may still be some routines not running on main thread, which would lead to this behaviour.
Does it work correctly outside of the nix packaging, eg native?

1 reply

ianmjones Feb 16, 2022
Author

On EndeavourOS (Arch Linux) I just checked out latest wails, installed v2 from checkout, created a project, fixed go.mod to local wails v2 checkout, built project and ran it a few times ... no fatal errors.

So probably something related to how things are linked up on NixOS. 🤷

I'll have another play on NixOS tonight and see if I can get some more debug info.

diogox · 2022-02-16T19:56:33Z

diogox
Feb 16, 2022

Hi 👋

Tbh I'm a bit confused by how you managed to run wails at all by fetching it from Github.

Like you, I have managed to get this working on my local machine by using a shell.nix file to add some dependencies I haven't yet figured out how to inject into the Nix derivation. But I also had to clone the project and do some manual edits to support NixOS, otherwise I'd always get an error saying my OS wasn't supported. So my derivation currently points to a local folder, where I have this "hacked" version of Wails.

Despite that, here's what I have, maybe it'll help:

Nix derivation

         buildGo117Module {
            name = "wails";

            src = ../../wails/v2;
            vendorSha256 = "sha256-jFXVDwJJP110mcqmayToBmTWKnyDctS0QdE6ICO5IFc=";

            subPackages = [ "cmd/wails" ];

            nativeBuildInputs = [ self.makeWrapper ];

            # Needed to be able to make a copy of Go below
            allowGoReference = true;
            postInstall = let
              pkgConfigPath = self.lib.makeBinPath [ self.pkg-config ];
            in
              ''
                # Injects the needed dependencies into pkg-config
                makeWrapper "${pkgConfigPath}/pkg-config" "$out/lib/pkg-config" \
                  --prefix PKG_CONFIG_PATH : "${
                    self.lib.concatStringsSep ":" [
                      "${self.gtk3.dev}/lib/pkgconfig"
                      "${self.webkitgtk.dev}/lib/pkgconfig"
                      "${self.pango.dev}/lib/pkgconfig"
                      "${self.glib.dev}/lib/pkgconfig"
                      "${self.harfbuzz.dev}/lib/pkgconfig"
                      "${self.atk.dev}/lib/pkgconfig"
                      "${self.cairo.dev}/lib/pkgconfig"
                      "${self.gdk-pixbuf.dev}/lib/pkgconfig"
                      "${self.libsoup.dev}/lib/pkgconfig"
                      "${self.zlib.dev}/lib/pkgconfig"
                    ]
                  }" \
                  --prefix LD_LIBRARY_PATH : "${
                    self.lib.concatStringsSep ":" [
                      "${self.gtk3.dev}/lib/pkgconfig"
                      "${self.webkitgtk.dev}/lib/pkgconfig"
                      "${self.pango.dev}/lib/pkgconfig"
                      "${self.glib.dev}/lib/pkgconfig"
                      "${self.harfbuzz.dev}/lib/pkgconfig"
                      "${self.atk.dev}/lib/pkgconfig"
                      "${self.cairo.dev}/lib/pkgconfig"
                      "${self.gdk-pixbuf.dev}/lib/pkgconfig"
                      "${self.libsoup.dev}/lib/pkgconfig"
                      "${self.zlib.dev}/lib/pkgconfig"
                    ]
                  }"

                # Wails runs Go directly, so we need to give it access to it. We need to copy it, so we can wrap it below.
                cp ${self.go_1_17}/bin/go $out/lib

                # Without the shell.nix file, I get the following error when "wails dev" is run:
                # ---
                # Compiling application: # github.com/wailsapp/wails/v2/internal/frontend/desktop/linux
                # /nix/store/h19zwlkrp6b0hp3ypbqdcggnyarn3af6-binutils-2.35.2/bin/ld: cannot find -lz
                # collect2: error: ld returned 1 exit status
                # ---
                # This means that I'm missing some dependencies here, I think. In fact, some of these are probably not needed, but I ran out of ideas and just started adding stuff.
                wrapProgram $out/lib/go \
                  --prefix PATH : "${self.lib.makeBinPath [ self.webkitgtk self.gcc self.stdenv.cc.cc self.glibc ]}"

                # Inject dependencies into "wails" executable
                wrapProgram $out/bin/wails \
                  --prefix PATH : "$out/lib:${self.lib.makeBinPath [ self.webkitgtk self.gtk3 ]}"
            '';
          }

Please note that I had this inside an overlay, so this may need some tweaking to make it work. Namely, some of the self instances should be pkgs.
I'm also sure that some of the things here aren't necessary, but this is very much a WIP.

shell.nix

{ pkgs ? import <nixpkgs> {}, makeLibraryPath ? pkgs.lib.makeLibraryPath}:

pkgs.mkShell {
  buildInputs = with pkgs; [
    webkitgtk
  ];
}

With both of these I can run and build projects just fine.
I have seen it crash a few times, but not many, and I just figured it was due to the unstable nature of v2 🤔

2 replies

ianmjones Feb 17, 2022
Author

Tbh I'm a bit confused by how you managed to run wails at all by fetching it from Github.

It took the best part of a wet and windy Sunday!

It took some experimentation and reading to work out that I needed the latest commit from wails as v2.0.0-beta.30 was missing a couple of important fixes, and how to get the derivation to use the correct v2 sub path along with the subPackages.

But the real key to my success was finding in the nixpkgs manual or NixOS wiki (I forget which) that when pkg-config is added to nativeBuildInputs, it runs during the build of the derivation and analyses the buildInputs to create a wrapper. So this means there's no need of manually wrapping with makeWrapper to get PKG_CONFIG_PATH/LD_LIBRARY_PATH set up with the required dynamically linked libraries. I used propagatedBuildInputs rather than just buildInputs simply because that ensures that those packages are made available as a dependency, but pkg-config still analyses them.

I had experimented with all kinds of forms of wrapper and patchelf to try and get things sorted along the way, eventually stripping it back to the simpler form you see above.

Like you, I have managed to get this working on my local machine by using a shell.nix file to add some dependencies I haven't yet figured out how to inject into the Nix derivation.

Yeah, I think a shell.nix that effectively does the gtk3/webkitgtk wrapping while developing and manually building a wails project is a must.

But I think what we'll need to do is have a default.nix for the wails project itself that is used to actually build the final usable app. I'm going to look into how that could be done taking some cues from your example derivation that uses local src so that it could be used during dev time too, and then for production builds a slightly altered one with examples of fetchFromGithub etc in it alongside local src.

But I also had to clone the project and do some manual edits to support NixOS, otherwise I'd always get an error saying my OS wasn't supported. So my derivation currently points to a local folder, where I have this "hacked" version of Wails.

Ooh, what kinds of changes did you need to make?

ianmjones Mar 3, 2022
Author

Hey @diogox, I took a leaf out of your book and started using an overlay. That was a much better way of testing the build, thanks for the tip!

I now have a working overlay expression that does not have that pesky ld: cannot find -lz problem when compiling a wails app without using a nix-shell environment:

self: super: {
  wails = super.buildGoModule rec {
    pname = "wails";
    version = "v2.0.0-beta.32";

    src = super.fetchFromGitHub
      {
        owner = "wailsapp";
        repo = pname;
        rev = "${version}";
        sha256 = "j7kSFviDV54B/ztBmoabTbQSBZ5DRdGqrCPrijrIkvw=";
      } + "/v2";

    vendorSha256 = "qPMVsvud2L7hpXUOfYYMiO32JXff8ZZC34EsxFoSJ0g=";

    proxyVendor = true;

    subPackages = [ "cmd/wails" ];

    nativeBuildInputs = [
      super.pkg-config
      super.makeWrapper
    ];

    buildInputs = [
      super.gtk3
      super.webkitgtk
    ];

    doCheck = true;

    postFixup =
      let
        libPath = super.lib.makeLibraryPath buildInputs;
      in
      ''
        wrapProgram $out/bin/wails \
          --prefix LD_LIBRARY_PATH : ${libPath} \
          --set PKG_CONFIG_PATH "$PKG_CONFIG_PATH" \
          --set CGO_LDFLAGS "-L${super.lib.makeLibraryPath [ super.zlib ]}"
      '';

    meta = with super.lib; {
      description = "Build applications using Go + HTML + CSS + JS";
      homepage = "https://wails.io";
      license = licenses.mit;
      maintainers = with maintainers; [ ianmjones ];
      platforms = platforms.linux;
    };
  };
}

If I then build an app with wails build that is using a local checkout of my #1200 PR to fixup some race conditions I hit, it seems to work just fine.

So I guess the next step is to refine and make the above expression into something that can be submitted to nixpkgs, and also come up with an example expression that can be used for packaging a wails app from source, using wails from nixpkgs as the builder.

ianmjones · 2022-03-06T01:01:21Z

ianmjones
Mar 6, 2022
Author

I've submitted a PR to nixpkgs, hopefully it'll pass review and test. 🤞

NixOS/nixpkgs#162947

8 replies

ianmjones Mar 10, 2022
Author

The PR has been merged. 🎉

It'll take a little while for wails to make its way through the build and test infrastructure and hit the unstable channel, and then eventually the next stable release, but it's on its way!

As the package maintainer, I'll try and keep on top of new releases of Wails and keep the package up to date.

leaanthony Mar 10, 2022
Maintainer

Awesome Ian! Let me know how I can help 👍 Perhaps there's some automation that could be done?

ianmjones Mar 10, 2022
Author

A cool thing about nixpkgs is that it has a bot that periodically checks for new GitHub releases and proposes a new PR with updated version and checksum etc when it sees one. As the maintainer I'll get pinged to review and test it.

And even if that lags a bit, chances are I'll see releases of Wails and will create and test a new build for nixpkgs in a reasonable time frame.

As long as you carry on creating nice releases every now and then as you currently do, we should be just fine.

leaanthony Mar 10, 2022
Maintainer

Thanks again for your effort on this!

ianmjones Mar 12, 2022
Author

Just checked this morning, wails 2.0.0-beta.33 is now available on the nixpkgs unstable channel.

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

Building v2 apps on NixOS #1156

{{title}}

Replies: 3 comments 11 replies

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

Select a reply

Building v2 apps on NixOS #1156

ianmjones Feb 15, 2022

Replies: 3 comments · 11 replies

leaanthony Feb 16, 2022 Maintainer

ianmjones Feb 16, 2022 Author

diogox Feb 16, 2022

ianmjones Feb 17, 2022 Author

ianmjones Mar 3, 2022 Author

ianmjones Mar 6, 2022 Author

ianmjones Mar 10, 2022 Author

leaanthony Mar 10, 2022 Maintainer

ianmjones Mar 10, 2022 Author

leaanthony Mar 10, 2022 Maintainer

ianmjones Mar 12, 2022 Author

ianmjones
Feb 15, 2022

Replies: 3 comments 11 replies

leaanthony
Feb 16, 2022
Maintainer

ianmjones Feb 16, 2022
Author

diogox
Feb 16, 2022

ianmjones Feb 17, 2022
Author

ianmjones Mar 3, 2022
Author

ianmjones
Mar 6, 2022
Author

ianmjones Mar 10, 2022
Author

leaanthony Mar 10, 2022
Maintainer

ianmjones Mar 10, 2022
Author

leaanthony Mar 10, 2022
Maintainer

ianmjones Mar 12, 2022
Author