Third version of make-layer-stack to use add-symmetric on a tuple of LayerSpec

[lchao-jitx]

The third version of make-layer-stack with simplified interface and a version of add-symmetric that supports a tuple of LayerSpec and even-layers? flag

public defn make-layer-stack (name:String,
  series-of-top-layers:Tuple<Tuple<LayerSpec>>
      -- description:String = ?,
         soldermask:LayerSpec = ?,
         even-layers?:True|False = false) -> LayerStack :
  val stack = #LayerStack(One(name), description)
  ;Access pairs of outer-layers in reverse order
  for top-layers in in-reverse(series-of-top-layers) do :
    add-symmetric(top-layers, stack, even-layers? = even-layers?)
  ;Add soldermask
  if value?(soldermask) is LayerSpec :
    add-soldermask(value!(soldermask), stack)
  ;Return the LayerStack
  stack

Perhaps, we could rename even-layers? since it really indicates whether the center of the stackup has one single layer or two identical layers. Here is the enhanced add-symmetric

public defn add-symmetric (top-layers:Tuple<LayerSpec>, stack:LayerStack
      -- even-layers?:True|False = false) -> LayerStack :
  ;Verify input
  if length(top-layers) <= 1 :
    throw(Exception("Invalid argument: Expect two or more layers in the tuple. Found %_" % [top-layers]))
  ;Get layers from outermost to innermost layers
  val layers-vec = to-vector<LayerSpec> $ top-layers
  ;Add innermost layer
  if length(layers(stack)) == 0 and not even-layers? :
    val innermost = pop(layers-vec) ; layers-vec contains the remaining layers
    ;Add the innermost layer(s)
    add(layers(stack), innermost)
  ;Add the remaining layers
  val reversed-layers = reverse $ to-list $ layers-vec ; reversed order - from inner to outer layers
  add-top(reversed-layers, stack)
  add-bottom(reversed-layers, stack)
  stack