Merge pull request #26 from diniamo/nix

nix: add package

flake.nix

@@ -0,0 +1,24 @@
+{
+  description = "Watch anime in cli with Anilist Integration and Discord RPC ";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    systems.url = "github:nix-systems/default";
+  };
+
+  outputs = {
+    nixpkgs,
+    systems,
+    ...
+  }: {
+    packages = nixpkgs.lib.genAttrs (import systems) (
+      system: let
+        pkgs = nixpkgs.legacyPackages.${system};
+        package = pkgs.callPackage ./package.nix {};
+      in {
+        default = package;
+        curd = package;
+      }
+    );
+  };
+}

package.nix

@@ -0,0 +1,48 @@
+{
+  buildGoModule,
+  lib,
+  makeBinaryWrapper,
+  mpv,
+  rofi,
+  ueberzugpp,
+  withMpv ? true,
+  withRofi ? false,
+  withUeberzugpp ? false,
+}: let
+  inherit (lib) optional optionalString;
+
+  path = optional withMpv mpv
+    ++ optional withRofi rofi
+    ++ optional withUeberzugpp ueberzugpp;
+in
+  buildGoModule {
+    pname = "curd";
+    version = builtins.readFile ./VERSION.txt;
+
+    src = lib.fileset.toSource {
+      root = ./.;
+      fileset = lib.fileset.unions [
+        ./cmd
+        ./internal
+        ./vendor
+
+        ./go.mod
+        ./go.sum
+      ];
+    };
+
+    nativeBuildInputs = [makeBinaryWrapper];
+    vendorHash = null;
+
+    postPatch = optionalString (builtins.length path > 0) ''
+      wrapProgram $out/bin/curd --prefix PATH : ${lib.makeBinPath path}
+    '';
+
+    meta = {
+      description = "Watch anime in CLI with AniList Tracking, Discord RPC, and automatic intro/outro skipping";
+      homepage = "https://github.com/Wraient/curd";
+      license = lib.licenses.gpl3;
+      platforms = lib.platforms.unix;
+      mainProgram = "curd";
+    };
+  }