Add Firefox module (#191)

danth · Dec 14, 2023 · 41d2185 · 41d2185
1 parent b5ad31b
commit 41d2185
Showing 1 changed file with 29 additions and 0 deletions.
diff --git a/modules/firefox/hm.nix b/modules/firefox/hm.nix
@@ -0,0 +1,29 @@
+{ config, lib, ... }:
+
+let
+  profileSettings = {
+    settings = {
+      "font.name.monospace.x-western" = config.stylix.fonts.monospace.name;
+      "font.name.sans-serif.x-western" = config.stylix.fonts.sansSerif.name;
+      "font.name.serif.x-western" = config.stylix.fonts.serif.name;
+    };
+  };
+  makeProfileSettingsPair = profileName:
+    lib.nameValuePair profileName profileSettings;
+in {
+  options.stylix.targets.firefox = {
+    enable =
+      config.lib.stylix.mkEnableTarget "Firefox" config.programs.firefox.enable;
+
+    profileNames = lib.mkOption {
+      description = "The Firefox profile names to apply styling on.";
+      type = lib.types.listOf lib.types.str;
+      default = [ ];
+    };
+  };
+
+  config = lib.mkIf config.stylix.targets.firefox.enable {
+    programs.firefox.profiles = lib.listToAttrs
+      (map makeProfileSettingsPair config.stylix.targets.firefox.profileNames);
+  };
+}