fixed rate irm

src/FixedRateIrm.sol

@@ -0,0 +1,50 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.19;
+
+import {IIrm} from "../lib/morpho-blue/src/interfaces/IIrm.sol";
+import {IFixedRateIrm} from "./interfaces/IFixedRateIrm.sol";
+
+import {ErrorsLib} from "./libraries/ErrorsLib.sol";
+import {MarketParamsLib} from "../lib/morpho-blue/src/libraries/MarketParamsLib.sol";
+import {Id, MarketParams, Market} from "../lib/morpho-blue/src/interfaces/IMorpho.sol";
+
+/// @title FixedRateIrm
+/// @author Morpho Labs
+/// @custom:contact security@morpho.org
+contract FixedRateIrm is IFixedRateIrm {
+    using MarketParamsLib for MarketParams;
+
+    /* EVENTS */
+
+    /// @notice Emitted when a borrow rate is set.
+    event SetBorrowRate(Id indexed id, uint256 newBorrowRate);
+
+    /* STORAGE */
+
+    /// @notice Borrow rates.
+    mapping(Id => uint256) public _borrowRate;
+
+    /* SETTER */
+
+    /// @inheritdoc IFixedRateIrm
+    function setBorrowRate(Id id, uint256 newBorrowRate) external {
+        require(_borrowRate[id] == 0, ErrorsLib.RATE_ALREADY_SET);
+        require(newBorrowRate != 0, ErrorsLib.RATE_ZERO);
+
+        _borrowRate[id] = newBorrowRate;
+
+        emit SetBorrowRate(id, newBorrowRate);
+    }
+
+    /* BORROW RATES */
+
+    /// @inheritdoc IIrm
+    function borrowRateView(MarketParams memory marketParams, Market memory) external view returns (uint256) {
+        return _borrowRate[marketParams.id()];
+    }
+
+    /// @inheritdoc IIrm
+    function borrowRate(MarketParams memory marketParams, Market memory) external view returns (uint256) {
+        return _borrowRate[marketParams.id()];
+    }
+}

src/interfaces/IFixedRateIrm.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.5.0;
+
+import {IIrm} from "../../lib/morpho-blue/src/interfaces/IIrm.sol";
+import {Id} from "../../lib/morpho-blue/src/interfaces/IMorpho.sol";
+
+/// @title IAdaptiveCurveIrm
+/// @author Morpho Labs
+/// @custom:contact security@morpho.org
+interface IFixedRateIrm is IIrm {
+    /// @notice Sets the borrow rate for a market.
+    /// @dev A rate can be set by anybody, but only once.
+    /// @dev The creator of a market with this IRM would typically batch the creation with the setting of the rate.
+    function setBorrowRate(Id id, uint256 newBorrowRate) external;
+}

src/libraries/ErrorsLib.sol

@@ -11,4 +11,10 @@ library ErrorsLib {
 
     /// @dev Thrown when the caller is not Morpho.
     string internal constant NOT_MORPHO = "not Morpho";
+
+    /// @dev Thrown when the rate is already set for this market.
+    string internal constant RATE_ALREADY_SET = "rate already set";
+
+    /// @dev Thrown when trying to set the rate at zero.
+    string internal constant RATE_ZERO = "rate zero";
 }

test/forge/FixedRateIrmTest.sol

@@ -0,0 +1,60 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import "../../src/FixedRateIrm.sol";
+
+import "../../lib/forge-std/src/Test.sol";
+
+contract FixedRateIrmTest is Test {
+    using MarketParamsLib for MarketParams;
+
+    event SetBorrowRate(Id indexed id, uint256 newBorrowRate);
+
+    FixedRateIrm public fixedRateIrm;
+
+    function setUp() external {
+        fixedRateIrm = new FixedRateIrm();
+    }
+
+    function testSetBorrowRate(Id id, uint256 newBorrowRate) external {
+        vm.assume(newBorrowRate != 0);
+
+        fixedRateIrm.setBorrowRate(id, newBorrowRate);
+        assertEq(fixedRateIrm._borrowRate(id), newBorrowRate);
+    }
+
+    function testSetBorrowRateEvent(Id id, uint256 newBorrowRate) external {
+        vm.assume(newBorrowRate != 0);
+
+        vm.expectEmit(true, true, true, true, address(fixedRateIrm));
+        emit SetBorrowRate(id, newBorrowRate);
+        fixedRateIrm.setBorrowRate(id, newBorrowRate);
+    }
+
+    function testSetBorrowRateAlreadySet(Id id, uint256 newBorrowRate1, uint256 newBorrowRate2) external {
+        vm.assume(newBorrowRate1 != 0);
+        vm.assume(newBorrowRate2 != 0);
+        fixedRateIrm.setBorrowRate(id, newBorrowRate1);
+        vm.expectRevert(bytes(ErrorsLib.RATE_ALREADY_SET));
+        fixedRateIrm.setBorrowRate(id, newBorrowRate2);
+    }
+
+    function testSetBorrowRateRateZero(Id id) external {
+        vm.expectRevert(bytes(ErrorsLib.RATE_ZERO));
+        fixedRateIrm.setBorrowRate(id, 0);
+    }
+
+    function testBorrowRate(MarketParams memory marketParams, Market memory market, uint256 newBorrowRate) external {
+        vm.assume(newBorrowRate != 0);
+        fixedRateIrm.setBorrowRate(marketParams.id(), newBorrowRate);
+        assertEq(fixedRateIrm.borrowRate(marketParams, market), newBorrowRate);
+    }
+
+    function testBorrowRateView(MarketParams memory marketParams, Market memory market, uint256 newBorrowRate)
+        external
+    {
+        vm.assume(newBorrowRate != 0);
+        fixedRateIrm.setBorrowRate(marketParams.id(), newBorrowRate);
+        assertEq(fixedRateIrm.borrowRateView(marketParams, market), newBorrowRate);
+    }
+}